The Firewall service may not start when you enable 802.1Q VLAN tagging and integrated NLB in ISA Server 2004, Enterprise Edition with Service Pack 2 (912943)

RESOLUTION

By default, ISA Server 2004 SP2 does not enable 802.1Q VLAN tagging and integrated NLB on different interfaces of a network adapter. To enable this functionality, you must run the following Microsoft Visual Basic Scripting Edition (VBScript) file on the computer that is running ISA Server 2004, Enterprise Edition with SP2. To do this, follow these steps:

1. Copy the following text into Notepad:

   Sub AddAllowVLANandNLB()
   
   ' Create the root object.
   Dim root ' The FPCLib.FPC root object
   Set root = CreateObject("FPC.Root")
   
   'Declare the other objects needed.
   Dim array ' An FPCArray object
   Dim VendorSets ' An FPCVendorParametersSets collection
   Dim VendorSet ' An FPCVendorParametersSet object
   
   ' Get references to the array object
   ' and the network rules collection.
   Set array = root.GetContainingArray
   Set VendorSets = array.VendorParametersSets
   
   On Error Resume Next
   Set VendorSet = VendorSets.Item( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
   
   If Err.Number <> 0 Then
   Err.Clear
   
   ' Add the item
   Set VendorSet = VendorSets.Add( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
   CheckError
   WScript.Echo "New VendorSet added... " & VendorSet.Name
   
   Else
   WScript.Echo "Existing VendorSet found... value- " & VendorSet.Value("AllowVLANandNLB")
   End If
   
   if VendorSet.Value("AllowVLANandNLB") <> true Then
   
   Err.Clear
   VendorSet.Value("AllowVLANandNLB") = true
   
   If Err.Number <> 0 Then
   CheckError
   Else
   VendorSets.Save false, true
   CheckError
   
   If Err.Number = 0 Then
   WScript.Echo "Done with AllowVLANandNLB, saved!"
   End If
   End If
   Else
   WScript.Echo "Done with AllowVLANandNLB, no change!"
   End If
   
   End Sub
   
   Sub CheckError()
   
   If Err.Number <> 0 Then
   WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
   Err.Clear
   End If
   
   End Sub
   
   AddAllowVLANandNLB
   

2. In Notepad, click File, click Save As, and then type a name for the script. For example, type VBScriptName.vbs in the File name box, and then click Save.
3. Run the file that you saved in step 2.
4. Restart the Firewall service after you run the VBScript file.