How to change the SQL Server 2005 service accounts by using the Windows Management Instrumentation (WMI) Provider for Configuration Management (911839)

INTRODUCTION

Permissions on the accounts that are used by SQL Server 2005 services are managed by group membership. When you try to change the SQL Server service accounts by using the Windows Service Control Manager, you must manually remove the old accounts and then add the new accounts to the corresponding groups. Therefore, we recommend that you use SQL Server Configuration Manager to change the SQL Server service accounts.

SQL Server 2005 provides the WMI Provider for Configuration Management. You can use the WMI Provider for Configuration Management to manage changes to group membership and changes to service accounts. Specifically, you can use the WMI Provider for Configuration Management in a script file to simplify the operations. For example, you can repeatedly call a script file to automate changing the SQL Server service accounts each month.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

You can use the following script sample to change the SQL Server service accounts.

Set oArgs = WScript.Arguments


' Verify the inputs.

If oArgs.Count <> 5 Then
               WScript.Echo "Usage: ChangeSQLServiceAccounts.vbs MachineName InstaNcename ServiceType SQLAccount SQLPassword"
               WScript.Echo "ServiceType = 1 (SQLServer), 2 (Agent), 3 (FTE), 4 (DTS), 5 (AS), 6 (RS), 7 (Browser)"
               WScript.Echo "Example: ChangeSQLServiceAccounts.vbs . MSSQLServer 1 BuiltIn\System NULL"
               WScript.Quit(1)
Else

' Load the inputs into variables.

               strComputer = oArgs(0)
               strInstanceName = oArgs(1)
               strServiceType = oArgs(2)
               strAccountName = oArgs(3)
               strPassword = oArgs(4)
End If

' Get a WMI object for the SQL namespace.

Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\ROOT\microsoft\sqlserver\ComputerManagement")

' Get an instance for this specific service.

Set objSQLService = objWMIService.Get("SqlService.ServiceName=""" & strInstanceName & """,SQLServiceType=" & strServiceType)

' Obtain an InParameters object specific to the SQLService.SetServiceAccount method.

Set objInParam = objSQLService.Methods_("SetServiceAccount").inParameters.SpawnInstance_()

' Add the input parameters to the input object. 

objInParam.Properties_.item("ServiceStartName") = strAccountName
objInParam.Properties_.item("ServiceStartPassword") = strPassword

' Call the SetServiceAccount method, and pass in the input object.

Set objOutParams = objSQLService.ExecMethod_("SetServiceAccount", objInParam) 

'Check the return to see whether there were any errors.

If objOutParams.ReturnValue = 0 Then
    Wscript.Echo "The service account was changed to " & strAccountName 
Else
    Wscript.Echo "Could not change the service account to " & strAccountName & " due to error " & objOutParams.ReturnValue
End If

To use this script sample, follow these steps:

Copy the code into a text file, and then save the file as ChangeSQLServiceAccounts.vbs.
At a command prompt, locate the folder that contains this file, type ChangeSQLServiceAccounts, and then press ENTER.

How to change the SQL Server 2005 service accounts by using the Windows Management Instrumentation (WMI) Provider for Configuration Management (911839)

SUMMARY

INTRODUCTION

MORE INFORMATION