The dial-up connection to a remote network is continually dialed when a client computer makes a request for a URL that is not defined in any LDT in ISA Server 2004 (901109)

RESOLUTION

Service pack information

To resolve this problem, obtain the latest service pack for Internet Security and Acceleration Server 2004. For more information, click the following article number to view the article in the Microsoft Knowledge Base:

Hotfix Information

Hotfix information

A supported hotfix is now available from Microsoft, but it is only intended to correct the problem that is described in this article. Only apply it to systems that are experiencing this specific problem. This hotfix may receive additional testing. Therefore, if you are not severely affected by this problem, we recommend that you wait for the next ISA Server 2004 service pack that contains this hotfix.

To resolve this problem immediately, contact Microsoft Product Support Services to obtain the hotfix. For a complete list of Microsoft Product Support Services telephone numbers and information about support costs, visit the following Microsoft Web site:Note In special cases, charges that are ordinarily incurred for support calls may be canceled if a Microsoft Support Professional determines that a specific update will resolve your problem. The usual support costs will apply to additional support questions and issues that do not qualify for the specific update in question.

Prerequisites

To apply this hotfix on an ISA Server 2004, Standard Edition-based computer, you must have ISA Server 2004 Service Pack 1 (SP1) installed. For more information, click the following article number to view the article in the Microsoft Knowledge Base:

Restart requirement

If you are prompted to restart the computer, you must restart the computer after you apply this hotfix.

Hotfix replacement information

This hotfix does not replace any other hotfixes.

File information

The English version of this hotfix has the file attributes (or later file attributes) that are listed in the following table. The dates and times for these files are listed in Coordinated Universal Time (UTC). When you view the file information, it is converted to local time. To find the difference between UTC and local time, use the Time Zone tab in the Date and Time tool in Control Panel.

   Date         Time   Version          Size  File name
   ------------------------------------------------------
   05-Jun-2005  07:32  4.0.2163.271  365,792  Msphlpr.dll

After you apply the hotfix

After you apply the hotfix that is described in this article, enable the DontDialToGetADnsServer flag. When this flag is enabled, the connection will not be dialed if the requested URL is not defined in any LDT.

To enable the DontDialToGetADnsServer flag, use the following script:

Sub AddHotFixVPSValue(ValueName , Mode)

    ' Create the root obect.
    Dim root  ' The FPCLib.FPC root object
    Set root = CreateObject("FPC.Root")


   'Declare the other objects needed.
    Dim array       ' An FPCArray object
    Dim VendorSets  ' An FPCVendorParametersSets collection
    Dim VendorSet   ' An FPCVendorParametersSet object

    ' Get references to the array object and the network rules collection.
    Set array = root.GetContainingArray
    Set VendorSets = array.VendorParametersSets

 
    On Error Resume Next
    Set VendorSet = VendorSets.Item( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
	
    If Err.Number <> 0 Then
        Err.Clear
	if Mode= true then
	        ' Add the item
        	Set VendorSet = VendorSets.Add( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
	        CheckError
        	WScript.Echo "New VendorSet added... " & VendorSet.Name
	else
		WScript.Echo "VendorSet {143F5698-103B-12D4-FF34-1F34767DEabc} doesn't exist, no need to disable"
		WScript.Quit
	end if
    Else
        WScript.Echo "Existing VendorSet found... " & ValueName & "=" &  VendorSet.Value(ValueName)
    End If

    if VendorSet.Value(ValueName) <> mode then
            Err.Clear
	    VendorSet.Value(ValueName) = mode
	    If Err.Number <> 0 Then
	        CheckError
	    Else
	    VendorSets.Save false, true
	    CheckError
        	If Err.Number = 0 Then
	            WScript.Echo "Saved - " & ValueName & "=" &  VendorSet.Value(ValueName) 
        	End If
	    End If
    Else 
        WScript.Echo ValueName & "=" &  VendorSet.Value(ValueName) & ",No change needed!"
    End If
End Sub


Sub CheckError()
    If Err.Number <> 0 Then
        WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
        Err.Clear
    End If
End Sub


'main
Dim args,FlagName,Mode 
Set args = Wscript.Arguments
if args.Count < 2 then 
	WScript.echo "This script sets a VPS flag for ISA2004 hotfixes"
	WScript.echo "Usage: AddHotFixVPSValue <Flag Name> <DISABLE/ENABLE>"
	WScript.echo "Examples:"
	wscript.echo "To set the flag DontDialToGetADnsServer run: "
	WScript.echo  "		AddHotFixVPSValue DontDialToGetADnsServer ENABLE"
	WScript.echo "To disable the flag run: "
	WScript.echo "		AddHotFixVPSValue DontDialToGetADnsServer DISABLE"
	WScript.Quit
end if

'Parse Command line
FlagName = args(0)
select case UCASE(args(1))
case "DISABLE" 
	Mode =false
case "ENABLE"
	Mode = true
case else
	WScript.echo "Second parameter should be ENABLE/DISABLE"
	WScript.Quit
End select

AddHotFixVPSValue FlagName, Mode