FIX: A memory leak may occur when you use the Advanced Data Tablegram persistence mechanism to persist a hierarchical recordset to a Stream object in a Microsoft Data Access Components 2.8 application (898056)

MORE INFORMATION

Steps to reproduce the problem

1. Start Microsoft Visual Basic 6.0.
2. Create a Standard EXE project. By default, a form that is named Form1 is created.
3. Add a project reference to the Microsoft ActiveX Data Objects 2.8 Library.
4. Add two command buttons to the Form1 form. By default, the Command1 command button and the Command2 command button are created.
5. In the Caption property of the Command1 command button, type Memory Leak Test.
6. In the Caption property of the Command2 command button, type Memory No-Leak Test.
7. Add the following lines of code to the Form1 form.

   Private Sub Command1_Click()
   Call LeakTest
   End Sub
   
   Private Sub Command2_Click()
   Call NoLeakTest
   End Sub

8. Add a module to the project. By default, a module that is named Module1 is created.
9. Add the following lines of code to the Module1 module.

   Option Explicit
   
   ' The following procedure demonstrates a memory leak that occurs when you use the
   ' Advanced Data Tablegram (ADTG) persistence mechanism to persist a hierarchical
   ' recordset to a Stream object:
   Sub LeakTest()
       
       Dim g_rs As ADODB.Recordset
   
       Dim i           As Long
       Dim j           As Long
       Dim lIndLeak    As Long
       Dim sShape      As String
       Dim rsChild     As ADODB.Recordset
       Dim oStream     As ADODB.Stream
       
       ' Use the SHAPE command to create a disconnected hierarchical recordset.
       sShape = "SHAPE APPEND new adVarChar(14) as Field0, " & _
                            " new adVarChar(14) as Field1, " & _
                            " new adVarChar(14) as Field2, " & _
                            " new adVarChar(14) as Field3, " & _
                            " ((SHAPE APPEND new adVarChar(14) as chldField0, " & _
                                           " new adVarChar(14) as chldField1, " & _
                                           " new adVarChar(14) as chldField2, " & _
                                           " new adVarChar(14) as chldField3 " & _
                            "   ) RELATE Field0 to chldField0) as Field4 "
   
       ' Create the Recordset object.
       If g_rs Is Nothing Then
           Set g_rs = New ADODB.Recordset
           g_rs.CursorLocation = adUseClient
           g_rs.Open sShape, "Provider=MsDataShape;Data Provider=None;", adOpenStatic, adLockBatchOptimistic, adCmdText
       
           ' Insert data to the recordset.
           For i = 0 To 10000
               g_rs.AddNew
               g_rs(0).Value = "Value0" & i
               g_rs(1).Value = "Value1" & i
               g_rs(2).Value = "Value2" & i
               g_rs(3).Value = "Value3" & i
               Set rsChild = g_rs(4).Value
               For j = 0 To 10
                   rsChild.AddNew
                   rsChild(0).Value = "Value0" & i
                   rsChild(1).Value = "Value1" & j
                   rsChild(2).Value = "Value2" & j
                   rsChild(3).Value = "Value3" & j
                   rsChild.Update
               Next j
               g_rs.Update
               
           Next i
           Set rsChild = Nothing
       End If
       
       MsgBox "Start the memory leak test."
       
       ' The following loop generates the memory leak. You create a Stream object, save
       ' the previously generated recordset to the Stream object, close the Stream object,
       ' and then release the Stream object. You notice that some memory
       ' that was allocated in the process of saving the recordset is not released.
       For lIndLeak = 0 To 20
       
          Set oStream = New Stream
          Call g_rs.Save(oStream, adPersistADTG)
       
          oStream.Close
          Set oStream = Nothing
          
       Next lIndLeak
       
       MsgBox "End the memory leak test."
       
       ' The memory is released only after you close and then release the original 
       ' recordset. To do this, uncomment the following two lines of code:
       
       'g_rs.Close
       'Set g_rs = Nothing
       
       ' If you do not release the recordset by using the previous line of code, and if
       ' g_rs is a global variable, the memory will continue to be used.
   End Sub
   
   ' The following procedure demonstrates that no memory leak occurs when you use the
   ' Advanced Data Tablegram (ADTG) persistence mechanism to persist a nonhierarchical
   ' recordset to a Stream object:
   Sub NoLeakTest()
   
       Dim g_rs As ADODB.Recordset
   
       Dim i           As Long
       Dim j           As Long
       Dim lIndLeak    As Long
       Dim sShape      As String
       Dim rsChild     As ADODB.Recordset
       Dim oStream     As ADODB.Stream
       
       ' Use the SHAPE command to create a disconnected nonhierarchical recordset.
       ' Notice that the part of the code that you used to create the hierarchical recordset 
       ' has been commented to make sure that you create a nonhierarchical recordset.
       sShape = "SHAPE APPEND new adVarChar(14) as Field0, " & _
                            " new adVarChar(14) as Field1, " & _
                            " new adVarChar(14) as Field2, " & _
                            " new adVarChar(14) as Field3 " '& _
   '                         " ((SHAPE APPEND new adVarChar(14) as chldField0, " & _
   '                                        " new adVarChar(14) as chldField1, " & _
   '                                        " new adVarChar(14) as chldField2, " & _
   '                                        " new adVarChar(14) as chldField3 " & _
   '                         "   ) RELATE Field0 to chldField0) as Field4 "
   
       ' Create the Recordset object.
       If g_rs Is Nothing Then
           Set g_rs = New ADODB.Recordset
           g_rs.CursorLocation = adUseClient
           g_rs.Open sShape, "Provider=MsDataShape;Data Provider=None;", adOpenStatic, adLockBatchOptimistic, adCmdText
       
           ' Insert data to the recordset.
           For i = 0 To 10000
               g_rs.AddNew
               g_rs(0).Value = "Value0" & i
               g_rs(1).Value = "Value1" & i
               g_rs(2).Value = "Value2" & i
               g_rs(3).Value = "Value3" & i
               ' Notice that the next eight lines of code have been commented because
               ' they correspond to code for the hierarchical recordset.
   '            Set rsChild = g_rs(4).Value
   '            For j = 0 To 10
   '                rsChild.AddNew
   '                rsChild(0).Value = "Value0" & i
   '                rsChild(1).Value = "Value1" & j
   '                rsChild(2).Value = "Value2" & j
   '                rsChild(3).Value = "Value3" & j
   '            Next j
               g_rs.Update
           Next i
           ' The following line of code has also been commented because it corresponds to
           ' the hierarchical recordset.
   '        Set rsChild = Nothing
       End If
       
       MsgBox "Start the memory no-leak test."
       
       ' The following loop does not generate a memory leak because you are using a
       ' nonhierarchical recordset.
       For lIndLeak = 0 To 20
       
          Set oStream = New Stream
          Call g_rs.Save(oStream, adPersistADTG)
          
          oStream.Close
          Set oStream = Nothing
       
       Next lIndLeak
       
       MsgBox "End the memory no-leak test."
       
       ' The following code is not required because there is no memory leak:
       'g_rs.Close
       'Set g_rs = Nothing
   End Sub 

10. Run the application. The Form1 form appears.
11. To test the memory leak scenario, click Memory Leak Test. To test the no-leak scenario, click Memory No-Leak Test.