Session state management may not work as expected when ISA Server 2004 accesses a Web site that uses the round robin feature of DNS to achieve load balancing (897075)

   Date         Time   Version       Size     File name
   -------------------------------------------------------
   17-May-2005  17:04  4.0.2163.259  654,608  W3filter.dll

   Date         Time   Version       Size     File name
   -------------------------------------------------------
   24-May-2005  05:53  4.0.3440.259  669,976  W3filter.dll

MORE INFORMATION

For more information, click the following article number to view the article in the Microsoft Knowledge Base: Important In ISA Server 2004, Enterprise Edition, this hotfix has no effect if the following two conditions are true:

• Network Load Balancing (NLB) is nonintegrated and is configured by using Network Load Balancing Manager.
• The affinity is set to "none."

If NLB is configured in integrated mode by using ISA Server Management, the hotfix effectively resolves the session state management problem. This hotfix prevents ISA Server from cycling through the IP address list when the round robin feature is being used. By defaut, however, ISA Server cycles through the IP address list. This hotfix does not change the default ISA Server behavior.

To prevent ISA Server from cycling through IP address lists, use the following script. This script sets a value named "DNSSearchValue" in a new vendor parameters set. The default behavior occurs when DNSSearchValue equals zero or does not exist at all. Any other value for DNSSearchValue forces the proxy to use a fixed IP address.

Note By using this script, you may reduce the effectiveness of the round robin feature for load balancing.

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' Copyright (c) Microsoft Corporation. All rights reserved.
' THIS CODE IS MADE AVAILABLE AS IS, WITHOUT WARRANTY OF ANY KIND. THE ENTIRE
' RISK OF THE USE OR THE RESULTS FROM THE USE OF THIS CODE REMAINS WITH THE
' USER. USE AND REDISTRIBUTION OF THIS CODE, WITH OR WITHOUT MODIFICATION, IS
' HEREBY PERMITTED.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' This script adds a new VendorParametersSets under the array root.
' add a new VendorParametersSet and add a value name "DNSSearchValue" set to 1.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Sub AddDNSSearchValue()

    ' Create the root object.
    Dim root  ' The FPCLib.FPC root object
    Set root = CreateObject("FPC.Root")

    ' Declare the other objects that are required.
    Dim array       ' An FPCArray object
    Dim VendorSets  ' An FPCVendorParametersSets collection
    Dim VendorSet   ' An FPCVendorParametersSet object

    ' Get references to the array object
    ' and the network rules collection.
    Set array = root.GetContainingArray
    Set VendorSets = array.VendorParametersSets

    On Error Resume Next
    Set VendorSet = VendorSets.Item( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )

    If Err.Number <> 0 Then
        Err.Clear

        ' Add the item
        Set VendorSet = VendorSets.Add( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
        CheckError
        WScript.Echo "New VendorSet added... " & VendorSet.Name

    Else
        WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value("DNSSearchValue")
    End If

    if VendorSet.Value("DNSSearchValue") <> 1 Then

        Err.Clear
        VendorSet.Value("DNSSearchValue") = 1

        If Err.Number <> 0 Then
            CheckError
        Else
            VendorSets.Save false, true
            CheckError

            If Err.Number = 0 Then
                WScript.Echo "Done, saved!"
            End If
        End If
    Else
        WScript.Echo "Done, no change!"
    End If

End Sub

Sub CheckError()

    If Err.Number <> 0 Then
        WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
        Err.Clear
    End If

End Sub

AddDNSSearchValue

When arrays are used, similar symptoms may occur because of Cache Array Routing Protocol (CARP). CARP exceptions can be configured in ISA Server 2004.
For more information about how to install ISA Server 2004 hotfixes and updates, click the following article number to view the article in the Microsoft Knowledge Base: