XADM: Cannot Move a Public Folder (829736)

MORE INFORMATION

How to Determine If a Folder Is a NewsGroup or a NewsGroup Anchor Folder

By default, the Internet Newsgroups folder is marked as a NewsGroup Anchor folder. Because of this, all folders that are created under the Internet Newsgroups public folder are marked as NewsGroup folders. Additionally, you can configure a public folder to be marked as a NewsGroup Anchor folder by linking it to an NNTP virtual directory. To do so, follow these steps:

1. Start Exchange System Manager.
2. If Administrative groups are enabled, expand Administrative Groups, and then expand your administrative group.
3. Expand Servers, expand your server, expand Protocols, expand NNTP, and then expand an NNTP virtual server.
4. Under the NNTP virtual server, right-click Virtual Directories, point to New, and then click Virtual Directory.
5. In New NNTP Virtual Directory Wizard, type a name in the Newsgroup subtree box, and then click Next.
6. Click Exchange Public Folder Database, and then click Next.
7. Click Browse, locate the public folder that you want to link to this NNTP virtual directory, and then click OK.
8. Click Finish.
9. Restart the Network News Transport Protocol (NNTP) service.

After you restart the Network News Transport Protocol (NNTP) service, the public folder is marked as a NewsGroup Anchor folder. Additionally, all public folders under the public folder that you linked to the NNTP virtual directory are marked as NewsGroup folders. All folders that you later create under this folder are marked as NewsGroup folders.

How to Locate the PR_IS_NEWSGROUP Property

All the NewsGroup folders are located under NewsGroup Anchor folders. Therefore, to locate NewsGroup folders, determine if a particular folder's parent folder is a NewsGroup Anchor folder.

How to Locate the PR_IS_NEWSGROUP_ANCHOR Property

You can find the NewsGroup Anchor folders by viewing the virtual directories for each Exchange computer in your organization. To do so, follow these steps:

1. Start Exchange System Manager.
2. If Administrative groups are enabled, expand Administrative Groups, and then expand your administrative group.
3. Expand Servers, expand your server, expand Protocols, expand NNTP, and then expand an NNTP virtual server.
4. Under your NNTP virtual server, click Virtual Directories.
5. In the right pane, view the public folders that correspond to the virtual directories.

You can also use the following Microsoft Visual Basic Scripting Edition script to locate the NewsGroup Anchor folders in your organization.

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

#######################################################################
#######################################################################

Option Explicit

'
' Loop through all public folders to check the PR_INTERNET_NEWSGROUP_NAME
'	property and to change the PR_IS_NEWSGROUP_ANCHOR property.
'

Dim tblFolderPath(20000) ' As String
Dim tblFolderID(20000) ' As String
Dim tblAnchorFolderPath(100) ' As String

Dim iNewsNameFolder ' As Integer
Dim iNewsAnchorFolder ' As Integer

Dim iNextFolder, iLastFolder ' As Integer     ' Next folder to process, last folder is filled in the array.
Dim iLastAnchorFolder 'As Integer
Dim oSession ' As MAPI.Session

GetAllFolder


Sub GetAllFolder()

    Dim oInfoStores ' As InfoStores
    Dim oInfoStore ' As InfoStore
    Dim oFolder ' As MAPI.Folder
    Dim bFound ' As Boolean
    Dim i,j ' As Integer
        
    '   Get first folder.
    
    wscript.echo "Before creating MAPI Session"
    Set oSession = wscript.CreateObject("MAPI.Session")  ' New MAPI.Session
    wscript.echo "Before Logging On"
    oSession.Logon 
    
    Set oInfoStores = oSession.InfoStores
    bFound = False
    wscript.echo " "
    wscript.echo "Looking for infostores..."
    For i = 1 To oInfoStores.Count
        wscript.echo "   infostore(" & i & ") " & oInfoStores.Item(i).ProviderName & ":" & oInfoStores.Item(i).Name
        If InStr(oInfoStores.Item(i).ProviderName, "Microsoft Exchange") > 0 Then
            If InStr(oInfoStores.Item(i).Name, "Public Folders") > 0 Then
                Set oInfoStore = oInfoStores.Item(i)
                bFound = True
            End If
        End If
    Next
    
    If Not bFound Then
        wscript.echo "ERROR: Did not find InfoStore Microsoft Exchange Server for a Public Folder Tree"
        exit sub
    Else
        wscript.echo "selected infostore " & oInfoStore.ProviderName & ":" & oInfoStore.Name
    End If
    wscript.echo " "
    
    tblFolderID(1) = oInfoStore.RootFolder.ID
    tblFolderPath(1) = ""
    
    iNextFolder = 1
    iLastFolder = 1
    iLastAnchorFolder = 0 
    iNewsNameFolder = 0
    iNewsAnchorFolder = 0

    
    While iNextFolder <= iLastFolder
        ProcessFolder (iNextFolder)
        iNextFolder = iNextFolder + 1
    Wend

    '   Summary
    
    wscript.echo " "
    wscript.echo "----------------------------------------------------------"
    wscript.echo "went through " & iLastFolder & " folders"
    wscript.echo "Number of folders with PR_INTERNET_NEWSGROUP_NAME set : " & iNewsNameFolder & " folders "
    wscript.echo "Number of folders with PR_IS_NEWSGROUP_ANCHOR set : " & iNewsAnchorFolder & " folders "
    wscript.echo "----------------------------------------------------------"
    wscript.echo " "
    wscript.echo "Folders with PR_IS_NEWSGROUP_ANCHOR set : " 
    wscript.echo " "
    
    For j=0 To iLastAnchorFolder 
	wscript.echo "  " & tblAnchorFolderPath(j)
    Next

    wscript.echo "----------------------------------------------------------"
    wscript.echo " "
    
End Sub

'
'   Fill in folder name.
'   Verify if there are subfolders, and then add them to the array.
'
Sub ProcessFolder(i)

    Dim oFolder ' As MAPI.Folder
    Dim SubFolders ' As MAPI.Folders
    Dim j ' As Integer
    Dim strParentPath ' As String
    Dim strNewsName ' As String
    Dim strNewsAnchor ' As String
    
    Set oFolder = oSession.GetFolder(tblFolderID(i))
    
    '   Adding Child folders.
    
    strParentPath = tblFolderPath(i)
        
    Set SubFolders = oFolder.Folders
    For j = 1 To SubFolders.Count
        iLastFolder = iLastFolder + 1
        tblFolderID(iLastFolder) = SubFolders.Item(j).ID
        tblFolderPath(iLastFolder) = strParentPath & "\" & SubFolders.Item(j).Name
        wscript.echo i & ": adding subfolder " & SubFolders.Item(j).Name & " as " & iLastFolder
    Next

    Set SubFolders = Nothing
    
    '   Dealing with PR_INTERNET_NEWSGROUP_NAME and PR_IS_NEWSGROUP_ANCHOR properties.
       
    On Error Resume Next
    strNewsName = ""
    strNewsAnchor = ""
    strNewsName = oFolder.Fields.Item(1722220574).Value
    strNewsAnchor = oFolder.Fields.Item(1721106443).Value
                                            
    On Error GoTo 0
    
    If Len(strNewsName) > 0 Then
        wscript.echo i & ": " & tblFolderPath(i) & " has PR_INTERNET_NEWSGROUP_NAME =" & strNewsName
	iNewsNameFolder = iNewsNameFolder + 1

    Else
        wscript.echo i & ": " & tblFolderPath(i) & " PR_INTERNET_NEWSGROUP_NAME is not set"
    End If

    If Len(strNewsAnchor) > 0 Then
	iLastAnchorFolder = iLastAnchorFolder + 1
	tblAnchorFolderPath(iLastAnchorFolder) = tblFolderPath(i)
        iNewsAnchorFolder = iNewsAnchorFolder + 1

    End If
    
    Set oFolder = Nothing
    
End Sub

#######################################################################
#######################################################################