HOW TO: Retrieve the Identity Value While Inserting Records into Access Database By Using Visual Basic .NET (815629)

MORE INFORMATION

Connect to the Access Database

1. Start Microsoft Visual Studio .NET 2002.
2. On the File menu, point to New, and then click Project.
3. Under Project Types, click Visual Basic Projects. Under Templates section, click Console Application. By default, Module1.vb is created.
4. Name the project MyJetApplication and then click OK.
5. Replace the existing code with the following code:

   Imports System
   Imports System.Data
   Imports System.Data.OleDb
   
   Module Module1
   
      Sub Main()
   
         ' Open Connection 
         Dim cnJetDB As OleDbConnection = New OleDbConnection("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=YourAccessDatabase")
         cnJetDB.Open()
   
         ' If the test table does not exist, create the Table.
         Dim strSQL As String
         strSQL = "CREATE TABLE AutoIncrementTest " & _
                  "(ID int identity, Description varchar(40), " & _
                  "CONSTRAINT AutoIncrementTest_PrimaryKey PRIMARY KEY (ID))"
   
         ' Command for creating Table.
         Dim cmdJetDB As New OleDbCommand(strSQL, cnJetDB)
         cmdJetDB.ExecuteNonQuery()
   
         ' Create a DataAdaptor With Insert Command For inserting records
         Dim oleDa As New OleDbDataAdapter("Select * from AutoIncrementTest", cnJetDB)
   
   
         ' Command to Insert Records.
         Dim cmdInsert As New OleDbCommand()
         cmdInsert.CommandText = "INSERT INTO AutoIncrementTest (Description) VALUES (?)"
         cmdInsert.Connection = cnJetDB
         cmdInsert.Parameters.Add(New OleDbParameter("Description", OleDbType.VarChar, 40, "Description"))
         oleDa.InsertCommand = cmdInsert
   
         ' Create a DataTable
         Dim dtTest As New DataTable()
         oleDa.Fill(dtTest)
   
         Dim drTest As DataRow
   
         ' Add Rows to the Table
         drTest = dtTest.NewRow
         drTest("Description") = "This is a Test Row 1"
         dtTest.Rows.Add(drTest)
   
         drTest = dtTest.NewRow
         drTest("Description") = "This is a Test Row 2"
         dtTest.Rows.Add(drTest)
         
      End Sub
   
   End Module
   

6. Modify the Data Source name in the connection string to point to your Access Database.

Trap the Identity Column Value

1. Add the following code before the Main method to create a second OleDbCommand object for the SELECT @@IDENTITY query:

      ' Create OleDbCommand for SELECT @@IDENTITY statement
      Private cmdGetIdentity As OleDbCommand

2. Append the following code to the Main method for creating a new instance of OleDbCommand class:

         ' Create another command to get IDENTITY value.
         cmdGetIdentity = New OleDbCommand()
         cmdGetIdentity.CommandText = "SELECT @@IDENTITY"
         cmdGetIdentity.Connection = cnJetDB
   
   

3. Append the following code to the Main method for handling the RowUpdated event:

         ' Delegate for handling RowUpdated event.
         AddHandler oleDa.RowUpdated, AddressOf HandleRowUpdated

4. Append the following code to the Main method for updating the data. The RowUpdated event is raised after calling the Update method.

         ' Update the Data
         oleDa.Update(dtTest)
   

5. Append the following code to the Main method to drop the AutoIncrementTest table and release the resources:

         ' Drop the table
         cmdJetDB.CommandText = "DROP TABLE AutoIncrementTest"
         cmdJetDB.ExecuteNonQuery()
   
         ' Release the resources.
         cmdGetIdentity.Dispose()
         cmdGetIdentity = Nothing
         cmdInsert.Dispose()
         cmdInsert = Nothing
         cmdJetDB.Dispose()
         cmdJetDB = Nothing
         cnJetDB.Close()
         cnJetDB.Dispose()
         cnJetDB = Nothing

6. Add the following RowUpdated event handler code to Module1:

      ' Event handler for RowUpdated event.
      Private Sub HandleRowUpdated(ByVal sender As Object, ByVal e As OleDbRowUpdatedEventArgs)
         If e.Status = UpdateStatus.Continue AndAlso e.StatementType = StatementType.Insert Then
            ' Get the Identity column value
            e.Row("ID") = Int32.Parse(cmdGetIdentity.ExecuteScalar().ToString())
            Debug.WriteLine(e.Row("ID"))
            e.Row.AcceptChanges()
         End If
      End Sub
   

7. On the Debug menu, click Start to run the application. Identity column values are displayed in the Output window.

Complete Code Listing

Imports System
Imports System.Data
Imports System.Data.OleDb

Module Module1

   ' Create OleDbCommand for SELECT @@IDENTITY statement
   Private cmdGetIdentity As OleDbCommand

   Sub Main()

      ' Open Connection 
      Dim cnJetDB As OleDbConnection = New OleDbConnection("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=YourAccessDatabase")
      cnJetDB.Open()

      ' If the test table does not exist then create the Table
      Dim strSQL As String
      strSQL = "CREATE TABLE AutoIncrementTest " & _
               "(ID int identity, Description varchar(40), " & _
               "CONSTRAINT AutoIncrementTest_PrimaryKey PRIMARY KEY (ID))"

      ' Command for Creating Table
      Dim cmdJetDB As New OleDbCommand(strSQL, cnJetDB)
      cmdJetDB.ExecuteNonQuery()

      ' Create a DataAdaptor With Insert Command For inserting records
      Dim oleDa As New OleDbDataAdapter("Select * from AutoIncrementTest", cnJetDB)


      ' Command to Insert Records
      Dim cmdInsert As New OleDbCommand()
      cmdInsert.CommandText = "INSERT INTO AutoIncrementTest (Description) VALUES (?)"
      cmdInsert.Connection = cnJetDB
      cmdInsert.Parameters.Add(New OleDbParameter("Description", OleDbType.VarChar, 40, "Description"))
      oleDa.InsertCommand = cmdInsert

      ' Create a DataTable
      Dim dtTest As New DataTable()
      oleDa.Fill(dtTest)

      Dim drTest As DataRow

      ' Add Rows to the Table
      drTest = dtTest.NewRow
      drTest("Description") = "This is a Test Row 1"
      dtTest.Rows.Add(drTest)

      drTest = dtTest.NewRow
      drTest("Description") = "This is a Test Row 2"
      dtTest.Rows.Add(drTest)

      ' Create another Command to get IDENTITY Value
      cmdGetIdentity = New OleDbCommand()
      cmdGetIdentity.CommandText = "SELECT @@IDENTITY"
      cmdGetIdentity.Connection = cnJetDB

      ' Delegate for Handling RowUpdated event
      AddHandler oleDa.RowUpdated, AddressOf HandleRowUpdated

      ' Update the Data
      oleDa.Update(dtTest)

      ' Drop the table
      cmdJetDB.CommandText = "DROP TABLE AutoIncrementTest"
      cmdJetDB.ExecuteNonQuery()

      ' Release the Resources
      cmdGetIdentity.Dispose()
      cmdGetIdentity = Nothing
      cmdInsert.Dispose()
      cmdInsert = Nothing
      cmdJetDB.Dispose()
      cmdJetDB = Nothing
      cnJetDB.Close()
      cnJetDB.Dispose()
      cnJetDB = Nothing
   End Sub

   ' Event Handler for RowUpdated Event
   Private Sub HandleRowUpdated(ByVal sender As Object, ByVal e As OleDbRowUpdatedEventArgs)
      If e.Status = UpdateStatus.Continue AndAlso e.StatementType = StatementType.Insert Then
         ' Get the Identity column value
         e.Row("ID") = Int32.Parse(cmdGetIdentity.ExecuteScalar().ToString())
         Debug.WriteLine(e.Row("ID"))
         e.Row.AcceptChanges()
      End If
   End Sub
End Module