How to use the HttpWebRequest class and the HttpWebResponse class to retrieve the properties of an object in Visual Basic .NET (314197)

MORE INFORMATION

1. Start Microsoft Visual Studio .NET.
2. On the File menu, point to New, and then click Project.
3. In the Visual Basic Projects types list, click Console Application.
   
   By default, the Module1.vb file is created.
4. In the code window, replace the code with the following:

   Imports System.Net
   Imports System.IO
   
   Module Module1
   
       Sub Main()
           ' TODO: Replace with the URL of an object on the computer that is running Exchange 2000.
           Dim sUri As String = "http://ExchServer/Exchange/UserAlias/Inbox/Test.EML"
   
           Dim myUri As System.Uri = New System.Uri(sUri)
           Dim HttpWRequest As HttpWebRequest = WebRequest.Create(myUri)
   
           Dim sQuery As String
           sQuery = "<?xml version='1.0'?>" & _
            "<a:propfind xmlns:a='DAV:' xmlns:m='urn:schemas:mailheader:'>" & _
            "<a:prop>" & _
            "<m:subject/>" & _
            "<a:isfolder/>" & _
            "<a:displayname/>" & _
            "<a:href/>" & _
            "</a:prop>" & _
            "</a:propfind>"
   
           ' TODO: Replace with the appropriate user credential.
           Dim myCred As NetworkCredential = New NetworkCredential("Domain\UserName", "Password")
           Dim MyCredentialCache As CredentialCache = New CredentialCache()
           MyCredentialCache.Add(myUri, "Basic", myCred)
           HttpWRequest.Credentials = MyCredentialCache
   
           ' Set the headers.
           HttpWRequest.KeepAlive = True 'this is the default
           HttpWRequest.Headers.Set("Pragma", "no-cache")
           HttpWRequest.Headers.Set("Translate", "f")
           HttpWRequest.ContentType = "text/xml"
           HttpWRequest.ContentLength = sQuery.Length
   
           'Set the request timeout to 5 minutes.
           HttpWRequest.Timeout = 300000
           ' set the request method
           HttpWRequest.Method = "PROPFIND"
   
   
           ' Store the data in a byte array.
           Dim ByteQuery() As Byte = System.Text.Encoding.ASCII.GetBytes(sQuery)
           HttpWRequest.ContentLength = ByteQuery.Length
           Dim QueryStream As Stream = HttpWRequest.GetRequestStream()
           ' write the data to be posted to the Request Stream
           QueryStream.Write(ByteQuery, 0, ByteQuery.Length)
           QueryStream.Close()
   
           ' Send the request and get the response.
           Dim HttpWResponse As HttpWebResponse = HttpWRequest.GetResponse()
   
           ' Get the status and the headers.
           Dim iStatCode As Integer = HttpWResponse.StatusCode
           Dim sStatus As String = iStatCode.ToString()
           Console.WriteLine("Status: {0} {1}", sStatus, HttpWResponse.StatusDescription.ToString())
   
           Console.WriteLine("Request Headers:")
           Console.WriteLine(HttpWRequest.Headers.ToString())
           Console.WriteLine("Response Headers:")
           Console.WriteLine(HttpWResponse.Headers.ToString())
   
           ' Get the response stream.
           Dim strm As Stream = HttpWResponse.GetResponseStream()
   
           ' Read the response stream.
           Dim sr As StreamReader = New StreamReader(strm)
           Dim sText As String = sr.ReadToEnd()
           Console.WriteLine("Response: {0}", sText)
   
           ' Close the stream.
           strm.Close()
   
           ' Clean up
           HttpWRequest = Nothing
           HttpWResponse = Nothing
           MyCredentialCache = Nothing
           myCred = Nothing
           strm = Nothing
           sr = Nothing
       End Sub
   End Module

5. Search for the TODO text string in the code, and then modify the code for your environment.
6. Press the F5 key to build and to run the program.
7. Make sure that the object properties have been retrieved from the response stream.