FIX: SOAP SDK: ConnectTimeout Does Not Apply to Dotted IP Address (311275)

MORE INFORMATION

Steps to Reproduce the Behavior

1. Save the following file as Calc.vbs.

   Option Explicit
   Const BASE_SOAP_ACTION_URI = "http://tempuri.org/action/Calc."
   Const WRAPPER_ELEMENT_NAMESPACE = "http://tempuri.org/message/"
   Const END_POINT_URL = "http://10.10.10.10/soaptest/Calc.asp"
   
   WScript.echo "Connecting: " & END_POINT_URL
   WScript.Echo "14+28=" & Execute(END_POINT_URL, "Add", 14,28)
   
   Function Execute(ByVal EndPointURL, ByVal Method, ByVal A, ByVal B)
   
       Dim Serializer
       Dim Reader
       Dim Connector
       
       Set Connector = CreateObject("MSSOAP.HttpConnector")
       Connector.Property("EndPointURL") = EndPointURL
       
       Connector.Property("SoapAction") = BASE_SOAP_ACTION_URI & Method
   
       'The "Timeout property only affects the SOAP request.
       'It does not effect the *connect* timeout.
       'It's always approx 20 seconds
       'This is in milliseconds
       Connector.Property("Timeout") = 1000
       'With this hotfix you can override the connect timeout by
       'using the "ConnectTimeOut" property
   '    Connector.Property("ConnectTimeOut") = 5000
       Connector.BeginMessage
       
       Set Serializer = CreateObject("MSSOAP.SoapSerializer")
       Serializer.Init Connector.InputStream
       
       Serializer.startEnvelope
       Serializer.startBody
       Serializer.startElement Method, WRAPPER_ELEMENT_NAMESPACE, , "m"
       Serializer.startElement "A"
       Serializer.writeString A
       Serializer.endElement
       Serializer.startElement "B"
       Serializer.writeString B
       Serializer.endElement
       Serializer.endElement
       Serializer.endBody
       Serializer.endEnvelope
       
       Connector.EndMessage
       
       Set Reader = CreateObject("MSSOAP.SoapReader")
       Reader.Load Connector.OutputStream
       
       If Not Reader.Fault Is Nothing Then
           Execute = "FAULT: " & Reader.faultstring.Text
       Else
           Execute = Reader.RPCResult.Text
       End If
       
   End Function
   					

2. Save the following file as Calc.asp

   <%@ LANGUAGE=VBScript %>
   <%
   
   Option Explicit
   
   Private Const WRAPPER_ELEMENT_NAMESPACE = "http://tempuri.org/message/"
   
   Response.ContentType = "text/xml"
   If Not Process() Then
     Response.Status = "500 Internal Server Error"
   End If  
   
   Public Function Process()
       Dim A
       Dim B
       Dim Answer
       Dim Serializer
       Dim Reader
       Dim MethodName
       Dim Parameter
       
       On Error Resume Next
       
       Process = False
       
       Set Reader = Server.CreateObject("MSSOAP.SoapReader")
       If Err Then
           ServerFault "Cannot create MSSOAP.SoapReader. " & Err.Description & "(0x" & Hex(Err.Number) & ")"
           Exit Function
       End If
       
       Reader.Load Request
       If Err Then
           ClientFault "Cannot load request. " & Err.Description
           Exit Function
       End If
       
       If Reader.RPCStruct Is Nothing Then
         ClientFault "No RPC wapper element found in request."
         Exit Function
       End If
       
       MethodName = Reader.RPCStruct.baseName
       If Err Then
           ClientFault "Cannot get method name. " & Err.Description
           Exit Function
       End If
       
       Set Parameter = Reader.RPCParameter("A")
       If Parameter Is Nothing Then
           ClientFault "Cannot find parameter A. " & Err.Description
           Exit Function
       End If
       A = CDbl(Parameter.Text)
       If Err Then
           ClientFault "Parameter A not a Double value. " & Err.Description
           Exit Function
       End If
       
       Set Parameter = Reader.RPCParameter("B")
       If Parameter Is Nothing Then
           ClientFault "Cannot find parameter B. " & Err.Description
           Exit Function
       End If
       B = CDbl(Parameter.Text)
       If Err Then
           ClientFault "Parameter B not a Double value. " & Err.Description
           Exit Function
       End If
       
       Select Case MethodName
       
           Case "Add"
               Answer = A + B
           
           Case "Subtract"
               Answer = A - B
           
           Case "Divide"
               Answer = A / B
           
           Case "Multiply"
               Answer = A * B
           
           Case Else
               ClientFault "Unknown method: """ & MethodName & """."
               Exit Function
       
       End Select
       
       Set Serializer = Server.CreateObject("MSSOAP.SoapSerializer")
       If Err Then
           ServerFault "Cannot create MSSOAP.SoapSerializer. " & Err.Description & "(0x" & Hex(Err.Number) & ")"
           Exit Function
       End If
       
       Serializer.Init Response
       
       Serializer.startEnvelope
       Serializer.startBody
       Serializer.startElement MethodName & "Response", WRAPPER_ELEMENT_NAMESPACE, , "m"
       Serializer.startElement "Result"
       Serializer.writeString CStr(Answer)
       Serializer.endElement
       Serializer.endElement
       Serializer.endBody
       Serializer.endEnvelope
       
       Process = True
       
   End Function
   
   Sub ServerFault(ByVal FaultString)
       
       ReturnFault "Server", FaultString
       
   End Sub
   
   Sub ClientFault(ByVal FaultString)
       
       ReturnFault "Client", FaultString
       
   End Sub
   
   Sub ReturnFault( ByVal FaultCode, ByVal FaultString)
   
       On Error Resume Next
       
       Err.Clear
       
       Dim Serializer
       
       Set Serializer = Server.CreateObject("MSSOAP.SoapSerializer")
       If Err Then
       
           Response.AppendToLog "Could not create SoapSerializer. " & Err.Description
           
       Else
       
           Serializer.Init Response
       
           Serializer.startEnvelope
           Serializer.startBody
           Serializer.startFault FaultCode, FaultString
           Serializer.startFaultDetail
           Serializer.endFaultDetail
           Serializer.endFault
           Serializer.endBody
           Serializer.endEnvelope
           
       End If
     
   End Sub
   %>  
   					

3. Create a directory named SoapTest on your disk.
4. Put the supplied Calc.vbs file on C:\SoapTest.
5. Create the virtual directory Soap in the Internet Information Services (IIS) and the local path for this virtual directory. This associates with the path where the Calc.asp and the Calc.vbs files are located.
6. Move to the command prompt.
7. Type ping 10.10.10.10 to make sure you cannot reach this address. You see:
   Request timed out
   iterated four times. If you cannot reach this address, go to step 9.
8. If you can reach 10.10.10.10, then edit the file c:\SoapTest\Calc.vbs and change the following line:
   
   Const END_POINT_URL = "http://10.10.10.10/Calc.asp"
   
   to read:
   
   Const END_POINT_URL = "http://ANOTHER_IP_ADDRESS/Calc.asp"
   
   where:
   
   ANOTHER_IP_ADDRESS is an IP address that you cannot reach.
9. Save the file, and then close the file.
10. Run the file, and then type wscript c:\soaptest\calc.vbs.
11. You receive a message box that displays the following:
    
    "Connecting http://10.10.10.10/Calc.asp"
12. After approximately a 20 second pause, a Microsoft VBScript runtime error is thrown:
    Script: c:\Soaptest\calc.vbs Line: 42 Char: 5 Error: Unknown runtime error Code: 800A151E Source: Microsoft VBScript runtime error
    Line 42 is the statement:
    Connector.EndMessage