BUG: GlobalMultiUse Class Does Not Terminate in Multithreaded Environment (300850)

MORE INFORMATION

Steps to Reproduce the Behavior

Create the DLL with a GlobalMultiUse Class

1. Create a new ActiveX DLL project with a default class, Class1.
2. From the Project menu, click Project1 Properties. Change the project name to GMultiUseDll, and then click OK.
3. In the Properties dialog box, set the Instancing property of Class1 to 6 - GlobalMultiUse.
4. Copy and paste the following code to Class1's code module:

   Public Function ClassName() As String
       ClassName = "Class1"
   End Function
   					

5. From the File menu, click Make GMultiUseDll.dll to compile the project. GMultiUseDll.dll is created.

Create the DLL with a MultiUse Class

1. Create a new ActiveX DLL project with a default class, Class1.
2. From the Project menu, click Project1 Properties. Change the project name to MultiUseDll, and then click OK.
3. From the Project menu, click References, select the GMultiUseDll.dll check box, and then click OK.
4. Copy and paste the following code to Class1's code module:

   Public Function GetString() As String
       GetString = ClassName
   End Function
   					

5. From the File menu, click Make MultiUseDll.dll to compile the project. MultiUseDll.dll is created.

Create the ActiveX EXE Project

1. Create a new ActiveX EXE project with a default class, Class1.
2. From the Project menu, click Project1 Properties. Change the project name to TestServer, and then click OK.
3. From the Project menu, click References, select the MultiUseDll.dll check box, and then click OK.
4. From the Project menu, click TestServer Properties. On the General tab, set the Thread Pool to 10 threads.
5. Copy and paste the following code to Class1's code module

   Public Sub DoSomething()
       Dim obj As MultiuseDll.Class1
       Set obj = New MultiuseDll.Class1
       obj.GetString
   End Sub
   					

6. From the File menu, click Make TextServer.exe to compile the project. TextServer.exe is created.

Create the Client Project

1. Create a new Standard EXE project with a default form, Form1.
2. From the Project menu, click Project1 Properties. Change the project name to TestClient, and then click OK.
3. Add a Label (Label1), a TextBox (Text1) and two CommandButtons (Command1 and Command2) to Form1.
4. Copy and paste the following code to Form1's code module:

   Dim bStop As Boolean
   
   Private Sub Command1_Click()
       Dim oServer As Object
       Set oServer = CreateObject("TestServer.Class1")
       WaitTRUEinFile Text1.Text
       oServer.DoSomething
       Set oServer = Nothing
       Label1.Caption = "The reference was released"
   End Sub
   
   ' The purpose of this function is to synchronize the call to the
   ' GlobalMultiUse DLL through the file Sync.txt.
   Private Sub WaitTRUEinFile(sFile As String)
       Dim sFlag      As String
       Label1.Caption = "Waiting for 'TRUE' in " & sFile
       Do While bStop = False
           Open sFile For Input As #1
           Line Input #1, sFlag
           Close #1
           
           If UCase(Trim(sFlag)) = "TRUE" Then
               Exit Do
           End If
           DoEvents
       Loop
   End Sub
   
   Private Sub Command2_Click()
       bStop = True
   End Sub
   
   Private Sub Form_Load()
       Text1.Text = "c:\sync.txt"
       Command1.Caption = "Start"
       Command2.Caption = "Stop"
       bStop = False
   End Sub
   
   Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
       bStop = True
   End Sub
   					

5. From the File menu, click Make TestClient.exe to compile the project. TestClient.exe is created.

Run the Test

1. Open Notepad. Add the letter "t" to the first position, and save the file as Sync.txt in the root of drive C.
2. Start two instances of TestClient.exe. Notice that two TestClient.exe processes are running in Task Manager.
3. Click Start for both instances of TestClient.
4. Open Sync.txt. Change the first line to "true," and save.
   
   After you save the file, notice the TestServer.exe process in Task Manager.
5. Click Stop for both instances of TestClient, and close the forms. Notice that there are no instances of TestClient.exe running. At this point, TestServer.exe stays loaded.