FIX: Unable to Replicate COM+ Package Due to Path Not Found 0x80070003 (292039)

RESOLUTION

To resolve this problem, obtain the latest service pack for Windows 2000. For additional information, click the following article number to view the article in the Microsoft Knowledge Base: This fix is included with the fixes that are described in the following Microsoft Knowledge Base article:

WORKAROUND

You can use any of the following methods to work around this problem:

• Change the instancing of the effected components to allow public instanciation.
  
  For example, in Microsoft Visual Basic 6.0, change the instancing of the effected class modules to MultiUse or GlobalMultiUse, recompile, and then reregister with Component Services.
• Manually install the components. Export the COM+ package from Component Services (this creates .msi and .cab files), copy the exported files to the target server, and then execute the .msi file.
• Run the following script to remove the component entries in the COM+ catalog that cause this problem. (Removing these components should not affect the operation of your applications because these catalog entries serve no purpose.)

  '********************************************************************
  '*
  '* File:           acCleanPublicNotCreatable.VBS
  '* Created:        February 2001
  '*
  '*  Main Function:  Deletes VB PublicNotCreatable components from COM+ catalog
  '*                  This corrects a problem that may cause AC2000 COM+ deployment failures
  '*
  '* Copyright (C) 2001 Microsoft Corporation
  '*
  '********************************************************************
  Option Explicit
  
  '  Open a session with the catalog
  '  Instantiate a COMAdminCatalog object
  Dim Catalog ' As COMAdminCatalog
  Set Catalog = CreateObject("COMAdmin.COMAdminCatalog")
  
  '  First get the "Applications" collection from the catalog,
  '  representing it with the generic COMAdminCatalogCollection
  Dim Applications ' As COMAdminCatalogCollection
  Set Applications = Catalog.GetCollection("Applications")
  Applications.Populate
  
  Dim app ' As COMAdminCatalogObject
  Dim Components ' As COMAdminCatalogCollection
  Dim comp ' As COMAdminCatalogObject
  Dim fUpdate ' As Boolean
  Dim i ' As Integer
  
  ' Walk Applications Collection
  
  For Each app In Applications
      'wscript.echo app.Name
  
      ' Get Components collection for current application
      Set Components = Applications.GetCollection("Components", app.Key)
      Components.Populate
  
      fUpdate = False
      i = 0
      ' Walk Compnents collection checking for empty Dll Path (PublicNotCreatable)
      For Each comp In Components
          ' Wscript.echo Components.Item(i).Name
          If comp.Value("DLL") = "" Then
              fUpdate = True
              wscript.echo "Removing " & comp.Name & " " & comp.Key & " from Application " & app.Name
              Components.Remove i
          Else
              i = i + 1
          End If
      Next
      If fUpdate Then Components.SaveChanges
  Next