Procedure to export a text file with both comma and quote delimiters in Excel (291296)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

You can use the Print # statement in a Visual Basic procedure that is similar to the following to export a text file with both quotation marks and commas as the delimiters. For the procedure to function correctly, select the cells that contain your data before you run it.

Before you work with the following example, follow these steps:

1. Open a new workbook.
2. On the Tools menu, point to Macro, and then click Visual Basic Editor or press ALT+F11. In the Visual Basic Editor, click Module on the Insert menu.
3. Type or paste the following sample code in the module sheet:

   Sub QuoteCommaExport()
      ' Dimension all variables.
      Dim DestFile As String
      Dim FileNum As Integer
      Dim ColumnCount As Integer
      Dim RowCount As Integer
   
      ' Prompt user for destination file name.
      DestFile = InputBox("Enter the destination filename" _
         & Chr(10) & "(with complete path):", "Quote-Comma Exporter")
   
      ' Obtain next free file handle number.
      FileNum = FreeFile()
   
      ' Turn error checking off.
      On Error Resume Next
   
      ' Attempt to open destination file for output.
      Open DestFile For Output As #FileNum
   
      ' If an error occurs report it and end.
      If Err <> 0 Then
         MsgBox "Cannot open filename " & DestFile
         End
      End If
   
      ' Turn error checking on.
      On Error GoTo 0
   
      ' Loop for each row in selection.
      For RowCount = 1 To Selection.Rows.Count
   
         ' Loop for each column in selection.
         For ColumnCount = 1 To Selection.Columns.Count
   
            ' Write current cell's text to file with quotation marks.
            Print #FileNum, """" & Selection.Cells(RowCount, _
               ColumnCount).Text & """";
   
            ' Check if cell is in last column.
            If ColumnCount = Selection.Columns.Count Then
               ' If so, then write a blank line.
               Print #FileNum,
            Else
               ' Otherwise, write a comma.
               Print #FileNum, ",";
            End If
         ' Start next iteration of ColumnCount loop.
         Next ColumnCount
      ' Start next iteration of RowCount loop.
      Next RowCount
   
      ' Close destination file.
      Close #FileNum
   End Sub
   					

4. Before you run the macro, select the data that you want to export, and then run the QuoteCommaExport subroutine.