ACC2000: How to Use the Seek Method with ActiveX Data Objects (ADO) Against a Jet Recordset (243465)

MORE INFORMATION

The following example illustrates how to use the Seek method to find a customer order with a particular Order ID and Product ID. If found, the example prints the quantity of the customer order in the Immediate window.

Usually, you can choose between using a client-side cursor library or one that is located on the server. In order for the Seek method to function, you must use a server-side cursor, as denoted in the CursorLocation property in the following code.

Also, you can only use the Seek method when a recordset is accessing the table directly. In this example, the recordset is instructed to access the table directly by the adCmdTableDirect argument in the Open method. You cannot use the Seek method on objects such as queries and linked tables. You can only use the Seek method on native Microsoft Jet tables. If your database contains linked tables, you can open an external connection to the back-end database that stores the table, and then use the Seek method directly on the table.

1. Create a new Microsoft Access 2000 database.
2. Click Modules under Objects, and then click New.
3. On the Tools menu, click References. Make sure the following two libraries are included in the Available References: box:
   • Microsoft ActiveX Data Objects 2.1 Library
   • Microsoft ADO Ext. 2.1 for DDL and Security
4. In the new module, type the following code:

   Function SeekRecord()
       Dim conn As ADODB.Connection
       Dim rst As ADODB.Recordset
   
       Set conn = New ADODB.Connection
       Set rst = New ADODB.Recordset
   
       'Set the connection properties and open the connection.
       With conn
           .Provider = "Microsoft.Jet.OLEDB.4.0"
           .ConnectionString = "C:\Program Files\Microsoft " _
               & "Office\Office\Samples\Northwind.mdb"
           .Open
       End With
   
       With rst
           'Select the index used in the recordset.
           .Index = "PrimaryKey"
   
           'Set the location of the cursor service.
           .CursorLocation = adUseServer
   
           'Open the recordset.
           .Open "Order Details", conn, adOpenKeyset, _
               adLockOptimistic, adCmdTableDirect
   
           'Find the customer order where OrderId = 10255 and ProductId = 16.
           .Seek Array(10255, 16), adSeekFirstEQ
   
           'If a match is found, print the quantity of the customer order.
           If Not rst.EOF Then
               Debug.Print rst.Fields("Quantity").Value
           End If
       End With
   End Function
   						

   Note that in the code, the path to Northwind.mdb may vary from computer to computer.
5. On the Debug menu, click Compile DatabaseName.
6. In the Immediate window, type the following line, and then press ENTER:

   SeekRecord