PPT2000: Sample VBA Code to Create a Graph from a Text File (222687)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. NOTE: The following macro examples work only in PowerPoint. Visual Basic for Applications macros are not supported by the Microsoft PowerPoint Viewer. For additional information, click the following article number to view the article in the Microsoft Knowledge Base:

Sample Visual Basic Procedure

   Sub CreateGraphFromFile()

      Dim oGraph As Object
      Dim oDataSheet As Object
      Dim shpGraph As PowerPoint.Shape
      Dim lRowCnt As Long
      Dim lColCnt As Long
      Dim lValue As Long

      ' Add the graph to the slide.
      With ActivePresentation.Slides(1)
         ' Create the Graph object on the slide.
         Set shpGraph = .Shapes.AddOLEObject(ClassName:="MSGraph.Chart", _
                                           Link:=msoFalse)
      End With

      ' Set references.
      Set oGraph = shpGraph.OLEFormat.Object
      Set oDataSheet = oGraph.Application.DataSheet

      ' Place headers into data table.
      ' Create four column headers.
      oDataSheet.Cells(1, 2).Value = "Col1"
      oDataSheet.Cells(1, 3).Value = "Col2"
      oDataSheet.Cells(1, 4).Value = "Col3"
      oDataSheet.Cells(1, 5).Value = "Col4"

      ' Create four row headers.
      oDataSheet.Cells(2, 1).Value = "Row1"
      oDataSheet.Cells(3, 1).Value = "Row2"
      oDataSheet.Cells(4, 1).Value = "Row3"
      oDataSheet.Cells(5, 1).Value = "Row4"

      ' We already know the number of columns and rows
      ' from the data we are importing.
      Open "<YourPathAndFileNameHere>" For Input As #1

      ' Get four rows of data.
      For lRowCnt = 2 To 5
         For lColCnt = 2 To 5

            ' Get value from file.
            Input #1, lValue

            ' Place in data table.
            oDataSheet.Cells(lRowCnt, lColCnt).Value = lValue
         Next lColCnt
      Next lRowCnt
      Close #1
      oDataSheet.Application.Update 
      ' Release the reference.
      Set oGraph = Nothing
      Set oDataSheet = Nothing

   End Sub