BUG: Tab Control Does Not Initialize Correctly from Load Event Using Control Array (214830)

RESOLUTION

Method 1

To work around this problem, move the code that places controls on the tabs from the load event to the Activate event of the form. Use a global flag to determine if the Activate event was fired without unloading the form. For example, use the sample project created in "Steps to Reproduce Behavior" below and follow these steps:

1. Move the code listed in step 5 from the Load event to the Activate event of Form1.
2. Modify the code in the Activate event by replacing it with the following:

   Dim i as integer
   If ActivateFlag = False Then
       For i = 1 To 3
           SSTab1.Tab = i - 1
           Load Text1(i)
           Set Text1(i).Container = SSTab1
           Text1(i).Top = i * (SSTab1.TabHeight + 100)
           Text1(i).Left = i * 200
           Text1(i).Visible = True
       Next i
       ActivateFlag = True
   End If
   					

3. From the Project menu, add a Standard Module (Module1) to the project and add the following line of code to Module1:

   Public ActivateFlag as Boolean
   					

4. Place the following line of code in the Unload event of Form1:

   ActivateFlag = False
   					

5. Run the application and note that all members of the TextBox control array are displayed on the correct tab.

Method 2

Another workaround is to place the control loading code in a global procedure. Call this procedure before calling the Show method for the form containing the tab control. For example:

1. Follow the steps 1 through 4 in "Steps to Reproduce Behavior" below.
2. From the Project menu, add a (BAS) Module to the project and copy and paste the following code to General Declarations area of Module1:

   Sub MyTabSetup()
       Dim i As Integer
       With Form1
           For i = 1 To 3
               .SSTab1.Tab = i - 1
               Load .Text1(i)
               Set .Text1(i).Container = .SSTab1
               .Text1(i).Top = i * (.SSTab1.TabHeight + 100)
               .Text1(i).Left = i * 200
               .Text1(i).Visible = True
           Next i
       End With
   End Sub
   					

3. Create a Sub Main procedure to be set as Startup object for the project by adding the following code to Module1:

   Sub Main()
   	MyTabSetup
   	Form1.Show
   End Sub
   					

4. From the Project menu, select Project1 Properties, and on the General tab, select Sub Main as the Startup Object.
5. Run the application and there should be one TextBox on each tab.
6. The procedure can also be called before the Show method of the form when ever the form needs to be displayed. For example, if the form was closed and needed to be shown from the click event of a CommandButton, simply place the following code in the click event of the CommandButton:

   Private Sub Command1_Click()
   	MyTabSetup
   	Form1.Show
   End Sub