XL2000: How to Copy Text to Text Boxes Using the Characters Method (213802)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Partner or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Partners, please visit the following Microsoft Web site: For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site: The first example Sub procedure (that is, TextBox_To_TextBox) demonstrates how to copy text from one text box drawing object into another text box. The second example Sub procedure, Cell_Text_To_TextBox, demonstrates a method that you can use to copy the value of a range of cells into a text box.

Example 1

To copy text from one text box drawing object into another text box, use the following code:

Sub TextBox_To_TextBox()

   ' Dimension the variables.
   Dim x As Integer
   Dim txtBox1 As TextBox, txtBox2 As TextBox
   Dim theText As String

   ' Set txtBox1 and txtBox2 equal to the active sheet's TextBox
   ' objects. Replace the ordinal number with your TextBox names
   ' in quotes. For example: ActiveSheet.DrawingObjects("Text 1")
   Set txtBox1 = ActiveSheet.DrawingObjects(1)
   Set txtBox2 = ActiveSheet.DrawingObjects(2)

   ' Create a For-Next construct that loops until there is no more
   ' text in txtBox1.
   For x = 1 To txtBox1.Characters.Count Step 250

      ' Place the first text box text into a variable called theText.
      theText = txtBox1.Characters(start:=x, Length:=250).Text

      ' Place the value of theText variable into second text box.
      txtBox2.Characters(start:=x, Length:=250).Text = theText
   Next

End Sub
				

Example 2

To copy the value of a range of cells into a text box, use the following code:

Sub Cell_Text_To_TextBox()

   ' Dimension the variables.
   Dim txtBox1 As TextBox
   Dim theRange As Range, cell As Range
   Dim startPos As Integer

   ' Set txtBox1 equal to the active sheet's TextBox object. You can
   ' replace the ordinal number with your text box name in quotes.
   ' For example: ActiveSheet.DrawingObjects("Text 1")
   Set txtBox1 = ActiveSheet.DrawingObjects(1)

   ' Set a range on the active sheet equal to the range object text
   ' that you are interested in copying to the text box.
   Set theRange = ActiveSheet.Range("A1:A10")

   'Set the starting position for the text.
   startPos = 1

  ' Create a For-Each construct to loop through the cells in the range.
   For Each cell In theRange

      ' Populate the textbox with the cell values using the Characters
      ' method.
      ' Note: Chr(10) can be used to add a new line in the textbox for
      ' each cell.
      txtBox1.Characters(start:=startPos, _
         length:=Len(cell.Value)).Text = cell.Value & Chr(10)

      ' Update the startPos variable to keep track of where the next
      ' string of text will begin in the textbox.
      startPos = startPos + Len(cell.Value) + 1
    Next cell
End Sub