WD2000: Simulating a Macro Pause in Visual Basic for Applications (212711)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
For more information about how to use the sample code in this article, click the article number below to view the article in the Microsoft Knowledge Base: You can simulate a pause in Visual Basic for Applications by using the following macro example. When the macro runs, it checks to see whether there is a command assigned to a specified keystroke. If there is no command assigned, the macro assigns itself as the command. When the key combination is used in a Word document, this macro example resumes execution and at the same time disables the key assignment made previously.

NOTE: Replace the key constants in this example with the key combination you want to use.

Sub MacroPauseExample()

Dim mykey as Variant

   'Set the Normal.dot to hold keyboard changes.
   CustomizationContext = NormalTemplate

   ' Determine Pause State by looking at the
   ' specified key combination command assignment.
   Set mykey = KeyBindings.Key(BuildKeyCode _
   (wdKeyControl, wdKeyAlt, wdKeyA))

   ' If there is no Command assignment (meaning
   ' the macro is not in a paused state.)
   If (mykey Is Nothing) Then

      ' ------------------------------------------------------
      ' <Place your code to run, BEFORE the pause occurs, here.>
      ' ------------------------------------------------------

      ' Pause the macro.
      KeyBindings.Add KeyCode:=BuildKeyCode _
      (wdKeyControl, wdKeyAlt, wdKeyA), _
      KeyCategory:=wdKeyCategoryMacro, _
      Command:="MacroPauseExample"
      Exit Sub

      Else ' The macro has been paused. Clear the pause state.

      ' Sets the Normal.dot to hold keyboard changes.
      CustomizationContext = NormalTemplate

      ' Clear Pause State.(Clear the command associated
      ' with the specified key combination.)
      FindKey(BuildKeyCode(wdKeyControl, wdKeyAlt, wdKeyA)).Disable

   End If

   ' ------------------------------------------------------------
   ' <Place your code to run, AFTER the pause is complete, here.>
   ' ------------------------------------------------------------

End Sub