WD2000: Run-Time Error '424' Attempting to Ungroup Shape Objects (212671)

WORKAROUND

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. To work around this problem, add the Select method to the Group and Ungroup commands, as in the following sample code:

Sub UnGroupShapes()
   Dim sShape1 As Shape
   Dim sShape2 As Shape
   ' Create new blank document.
   Application.Documents.Add
   ' Create two shapes(Hexagon and Heart).
   With ActiveDocument.Shapes
      ' Add Hexagon shape.
      Set sShape1 = .AddShape(10, 122.4, 79.2, 72#, 72#)
      ' Add Heart shape.
      Set sShape2 = .AddShape(21, 230.4, 79.2, 72#, 72#)
   End With
   ' Select both shapes.
   sShape1.Select
   ' The (0) argument in the following command allows
   ' selection of the second shape without deselecting
   ' the first shape.
   sShape2.Select (0)
   With Selection.ShapeRange
      ' Group the shapes.
      .Group.Select
      ' UnGroup the shapes and leave them selected.
      .Ungroup.Select
   End With
End Sub
				

For this code to work properly, you can have the last two lines resemble the following example (which groups the objects, reselects them, ungroups them, and then deselects them):

   ' Group the shapes.
   Selection.ShapeRange.Group.Select
   ' UnGroup the shapes and leave them deselected.
   Selection.ShapeRange.Ungroup
				

Or you can use code similar to the following, as in the "Ungroupshapes" example (which groups the objects, selects them, ungroups them, and then leaves them selected):

   ' Group the shapes.
   Selection.ShapeRange.Group.Select
   ' UnGroup the shapes and leave them selected.
   Selection.ShapeRange.Ungroup.Select
				

For more information about grouping and ungrouping shapes, in the Visual Basic Editor, click Microsoft Visual Basic Help on the Help menu, type ShapeRange in the Office Assistant or the Answer Wizard, and then click Search to view the topic.