ACC2000: Sample Function to Determine Windows 95/98 or NT Version (210200)

MORE INFORMATION

Although the GetVersion() function is still supported under Win32, it has been superseded by GetVersionEx(), which identifies Windows 95/98, returns more accurate information about the build of Windows, and no longer returns the version of MS-DOS.

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. The following example function demonstrates how to use the GetVersionEx() Windows API function:

1. Create a module and type the following code in the Declarations section:
   

   '====================================
   ' Global Declarations
   '====================================
   
   Option Explicit
   
   Type OSVERSIONINFO
      dwOSVersionInfoSize As Long
      dwMajorVersion As Long
      dwMinorVersion As Long
      dwBuildNumber As Long
      dwPlatformId As Long
      szCSDVersion As String * 128   ' Maintenance string for PSS usage.
   End Type
   
   Public Const VER_PLATFORM_WIN32s = 0
   Public Const VER_PLATFORM_WIN32_WINDOWS = 1
   Public Const VER_PLATFORM_WIN32_NT = 2
   
   Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" _
     (lpVersionInformation As OSVERSIONINFO) As Long

   
   
2. Type the following procedure:

   Function SysVersions32()
   
      Dim v As OSVERSIONINFO, retval As Long
      Dim WindowsVersion As String, BuildVersion As String
      Dim PlatformName As String
   
      v.dwOSVersionInfoSize = Len(v)
      retval = GetVersionEx(v)
   
      WindowsVersion = v.dwMajorVersion & "." & v.dwMinorVersion
      BuildVersion = v.dwBuildNumber And &HFFFF&
   
      Select Case v.dwPlatformId
         Case VER_PLATFORM_WIN32_WINDOWS
            PlatformName = "Windows 95/98"
         Case VER_PLATFORM_WIN32_NT
            PlatformName = "Windows NT"
      End Select
   
      MsgBox "Platform: " & PlatformName & vbCrLf & _
         "Version: " & WindowsVersion & vbCrLf & _
         "Build: " & BuildVersion
   
   End Function

3. To test this function, type the following line in the Immediate window, and then press ENTER:

   ?SysVersions32()

   Note that the message box displays the operating system's name, version, and build number.

The GetVersionEx() function fills the OSVERSIONINFO structure, which contains elements for the operating system platform, version, and build information. Note that the element dwPlatformId could be any of the VER_PLATFORM_ constants listed at the top of the example.