WD2000: Macro to Cascade Open Document Windows (209202)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
The following example Visual Basic for Applications macro routine will cascade all open Single Document Interface (SDI) windows.

Sub CascadeWindows()

   Dim iVLap As Integer        'Vertical Window Overlap.
   Dim iHLap As Integer        'Horizontal Window Overlap.
   Dim lngTop As Long          'Cascaded Window Top.
   Dim lngLeft As Long         'Cascaded Window Left.
   Dim lngWidth As Long        'Cascaded Window Width.
   Dim lngHeight As Long       'Cascaded Window Height.
   Dim wDocWindow As Window    'Document Window Object.

   ' If no documents exist, exit this routine.
   If Documents.Count = 0 Then Exit Sub

   'Set document window to normal size.
   ActiveWindow.WindowState = wdWindowStateNormal

   'Calculate window sizes.
   iVLap = 14   'Vertical overlap
   iHLap = 28   'Horizontal overlap

   'Calculate width and height of windows in points.
   lngWidth = Application.UsableWidth - ((Windows.Count - 1) * iHLap)
   lngHeight = Application.UsableHeight - ((Windows.Count - 1) * iVLap)

   ' The following loop cascades the windows by calculating
   ' each document window size and then moves them into position.
   For Each wDocWindow In Windows
      Documents(wDocWindow).Activate
      With ActiveWindow
         .Top = lngTop
         .Left = lngLeft
         .Height = lngHeight
         .Width = lngWidth
      End With
      lngLeft = lngLeft + iHLap
      lngTop = lngTop + iVLap
   Next wDocWindow

End Sub
				

For more information about adding a command to a menu, click Microsoft Word Help on the Help menu, type Add a command or other item to a menu in the Office Assistant or the Answer Wizard, and then click Search to view the topic.

For more information about how to use the sample code in this article, click the article number below to view the article in the Microsoft Knowledge Base: