WD2000: How to Pass a Parameter to a Macro Using Automation (209149)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
For more information about how to use the sample code in this article, click the article number below to view the article in the Microsoft Knowledge Base: To pass a parameter to a Word Visual Basic for Applications macro using automation, you need to move your Word macro code to the ThisDocument object module of the document or template that contains the macro you are calling.

To move your macro to the ThisDocument module, follow these steps:

1. Open the document or template that contains the macro you are calling.
2. Press ALT+F11 to open the Word Visual Basic Editor.
3. Select the macro you want to move or copy.
4. On the Edit menu, click Copy to copy your macro, or click Cut to move your macro.
5. In the Project Explorer, double-click the document or template project to view Microsoft Word Objects.
6. Double-click Microsoft Word Objects, and then double-click ThisDocument.
7. Click in the ThisDocument code window.
8. On the Edit menu, click Paste to paste your code into the ThisDocument object module.
   
   For example, if the following macro existed in Word, paste it into the ThisDocument object module:

   Sub MyWordMacro(strPassedParam As String)
   
      MsgBox strPassedParam
   
   End Sub
   					

In the application you are using to automate Word, you can use one of the following example macros to call and pass a parameter to your Word macro.

Access Your Word Macro by Directly Opening a Document or Template

Use the following macro to open a document template or a document based on a template that contains your Word macro.

Sub AutomateWord_OpenDoc()

   Dim wrdApp As Object
   Dim wrdDoc As Object
   Dim strFileName As String
   Set wrdApp = CreateObject("Word.Application")

   On Error GoTo DocError

   ' Replace the following example string value with the path and
   ' file name of the document or template containing your macro.
   strFileName = "<Path and Filename of document or template>"

   ' Open the document or template and set a variable equal to the
   ' document or template.
   Set wrdDoc = wrdApp.Documents.Open(strFileName)

   ' Run the macro. (Replace "MyWordMacro" with the name of your macro.)
   wrdDoc.MyWordMacro ("This is a test.")

   DocError:
      If Err.Number <> 0 Then Msgbox Err.Description

      ' Quit this instance of Word.
      wrdApp.Quit

      ' Clear variable memory.
      Set wrdApp = Nothing
      Set wrdDoc = Nothing

   End Sub
				

Access a Document Based on the Template That Contains Your Macro

Use the following macro to create a new blank document based on a template that contains your Word macro.

Sub AutomateWord_OpenDoc()
   Dim wrdApp As Object
   Dim wrdDoc As Object
   Dim strFileName As String
   Set wrdApp = CreateObject("Word.Application")

   On Error GoTo DocError

   ' Replace the following example string value with the path and
   ' file name of the template containing your macro.
   strFileName = "<Path and Filename of template>"

   ' Open the document and set a variable equal to a new blank
   ' document and its underlying template.
   Set wrdDoc = wrdApp.Documents.Add(strFileName)

   ' Run the macro. (Replace "MyWordMacro" with the name of your macro.)
   wrdDoc.MyWordMacro ("This is a test.")

   DocError:

      If Err.Number <> 0 Then Msgbox Err.Description

      ' Quit this instance of Word.
      wrdApp.Quit

      ' Clear variable memory.
      Set wrdApp = Nothing
      Set wrdDoc = Nothing

End Sub