PRB: "No Such Interface Supported" Error Calling ADOX Method (198535)

MORE INFORMATION

Steps to Reproduce Behavior

1. Create a Standard EXE project in Visual Basic. Form1 is created by default.
2. From the Project menu, select References. Then, from the list of references, select the following:

   "Microsoft ADO Ext. 2.x for DDL and Security"
   "Microsoft ActiveX Data Objects 2.x Library"

3. Paste the following code into the default Load method of Form1. Modify the ConnectionString to connect to your SQL Server.

         Dim cnn As ADODB.Connection
         Dim cat As ADOX.Catalog
         Dim tbl As ADOX.Table
         Dim fky As ADOX.Key
         Dim idx As ADOX.Index
   
         Set cnn = CreateObject("ADODB.Connection")
         Set cat = CreateObject("ADOX.Catalog")
         Set fky = CreateObject("ADOX.Key")
         Set tbl = CreateObject("ADOX.Table")
         Set idx = CreateObject("ADOX.Index")
   
         'Uncomment the following line to see "Not Implemented" or "No such interface supported" error.
         'cat.Create "Provider=SQLOLEDB;Data Source=your_server;"
   
         With cnn
            .ConnectionString = "PROVIDER=sqloledb;" & _
                                "DATA SOURCE=your_server;" & _
                                "USER ID=<user name>;PASSWORD=<strong password>;" & _
                                "INITIAL CATALOG=pubs"
            .Open
         End With
   
         Set cat.ActiveConnection = cnn
   
         'Create a Parent table.
         With tbl
            .Name = "tbl_1"
            .Columns.Append "Col_1", adInteger
            .Columns.Append "Col_2", adVarChar, 10
         End With
   
         'Create a Primary Key on the Parent table.
         With idx
            .Clustered = False
            .Columns.Append "Col_1"
            .Name = "tbl_1_pk"
            .PrimaryKey = True
         End With
   
         'Add the Index to the table's Indexes collection.
         tbl.Indexes.Append idx
         'Actually create the table and index on the server.
         cat.Tables.Append tbl
   
         Set tbl = Nothing
         Set tbl = CreateObject("ADOX.Table")
   
         'Create a Child table.
         With tbl
            .Name = "tbl_2"
            .Columns.Append "Col_1", adInteger
            .Columns.Append "Col_2", adVarChar, 10
         End With
   
         'Create the Foreign Key.
         With fky
            .Columns.Append "Col_1"
            .Name = "fkey"
            .RelatedTable = "tbl_1"
            .Columns("Col_1").RelatedColumn = "Col_1"
            .Type = adKeyForeign
         End With
   
         'Add the Foreign key to the child table's Keys Collection.
         tbl.Keys.Append fky
         'Actually create the child table and Foreign Key on the Server.
         'This is the line that will generate the error :
         '"No such interface support"
         'Comment the previous line of code and the table will be
         'successfully created on the server, minus the Foreign Key.
         cat.Tables.Append tbl
   
         'To workaround the problem, you can add the Foreign Key via a SQL statement instead:
         'cat.ActiveConnection.Execute "ALTER TABLE tbl_2 ADD CONSTRAINT Col_1 " & _
                                       "FOREIGN KEY(Col_1) REFERENCES tbl_1(Col_1)"
   
   
   					

4. Run the form, and note the error that is raised on appending the table with the Foreign Key.