XL98: How to Copy Text to TextBoxes Using the Characters Method (192908)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. The first Sub procedure (that is, TextBox_To_TextBox) demonstrates how to copy text from one TextBox DrawingObject into another text box. The second Sub procedure Cell_Text_To_TextBox, demonstrates a method that you can use to copy the value of a range of cells into a text box.

The following Sub procedure copies the text from one text box on the active sheet to another text box on the active sheet.

Sample Visual Basic Procedures

  Sub TextBox_To_TextBox()

      ' Dimension the variables.
      Dim x As Integer
      Dim txtBox1 As TextBox, txtBox2 As TextBox
      Dim theText As String

      ' Set txtBox1 and txtBox2 equal to the active sheet's TextBox
      ' objects. Replace the ordinal number with your TextBox names
      ' in quotes. For example: ActiveSheet.TextBoxes("Text 1")
      Set txtBox1 = ActiveSheet.TextBoxes(1)
      Set txtBox2 = ActiveSheet.TextBoxes(2)

      ' Create a For-Next construct that loops until there is no more
      ' text in txtBox1.
      For x = 1 To txtBox1.Characters.Count Step 250

         ' Place the first text box text into a variable called theText.
         theText = txtBox1.Characters(start:=x, Length:=250).Text

         ' Place the value of theText variable into second text box.
         txtBox2.Characters(start:=x, Length:=250).Text = theText

      Next
   End Sub
				

The following Sub procedure copies the values from a range of cells that you specify into a text box on the active sheet.

NOTE: This subroutine cannot transfer more than 254 characters of text from a cell to a text box.

  Sub Cell_Text_To_TextBox()

      ' Dimension the variables.
      Dim txtBox1 As TextBox
      Dim theRange As Range, cell As Range
      Dim startPos As Integer

      ' Set txtBox1 equal to the active sheet's TextBox object. You can
      ' replace the ordinal number with your text box name in quotes.
      ' For example: ActiveSheet.TextBoxes("Text 1")
      Set txtBox1 = ActiveSheet.TextBoxes(1)

      ' Set a range on the active sheet equal to the range object text
      ' that you are interested in copying to the text box.
      Set theRange = ActiveSheet.Range("A1:A10")

      'Set the starting position for the text.
      startPos = 1

      ' Create a For-Each construct to loop through the cells in the range.
      For Each cell In theRange

         ' Populate the textbox with the cell values using the Characters
         ' method.
         ' Note: Chr(10) can be used to add a new line in the textbox for
         ' each cell.
         txtBox1.Characters(start:=startPos, _
            length:=Len(cell.Value)).Text = cell.Value & Chr(13)

         ' Update the startPos variable to keep track of where the next
         ' string of text will begin in the textbox.
         startPos = startPos + Len(cell.Value) + 1

      Next cell
   End Sub