ACC97: How to Run Macros in Other Office Programs (177760)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Partner or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Partners, please visit the following Microsoft Web site: For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site: The products listed at the beginning of this article all have very similar means of accessing a Sub procedure stored in their respective file formats. The following Sub procedures should work in any of the Microsoft Office programs. Any differences are noted.

To use any of these Sub procedures, you must place them in a module. Follow these steps to insert a module for the appropriate program.

Inserting a Module in Excel, PowerPoint or Word

1. Press ALT+F11 to start the Visual Basic Editor.
2. On the Insert menu, click Module.
3. Type the appropriate sample code (found later in this section) in the module.

Inserting a Module in Microsoft Access

1. In the database window, click the Modules tab.
2. Click New.
3. Type the appropriate sample code (found later in this section) in the module.

Sub Procedure to Run an Existing Microsoft Access Macro

The following Sub procedure assumes that the database AccessAutomation.mdb contains a macro called "AccessMacro."

      Sub AccessTest1()
      Dim A as Object

      Set A = CreateObject("Access.Application")
      A.Visible = False

      A.OpenCurrentDatabase("C:\My Documents\AccessAutomation.mdb")

      A.DoCmd.RunMacro "AccessMacro"

   End Sub
				

There are a couple of things to note when calling a Microsoft Access macro. First, when you use the CreateObject function to create an instance of Microsoft Access, it is always created as visible. All of the other Microsoft Office programs are created with the Visible property set to False by default.

Also, note that if a Microsoft Access Sub procedure displays a modal dialog box, such as a message box, Microsoft Access has to be activated manually using the Microsoft Windows 95 taskbar to view the dialog box. If the code does not display a modal dialog box, manual activation is not necessary. There is no way to do this activation programmatically with Automation. All of the other programs listed at the beginning of this article display dialog boxes without being activated.

Sub Procedure to Run an Existing Microsoft Excel Macro

The following Sub procedure assumes that the workbook ExcelFile.xls contains a macro called "TestMacro."

     Sub XLTest()
      Dim XL as Object

      Set XL = CreateObject("Excel.Application")

      XL.Workbooks.Open "C:\My Documents\ExcelFile.xls"

      ' If there is more than one macro called TestMacro,
      ' the module name would be required as in
      '
      ' XL.Run "Module1.TestMacro"
      '
      ' to differentiate which routine is being called.
      '
      XL.Run "TestMacro"

   End Sub
				

Sub Procedure to Run an Existing Microsoft PowerPoint Macro

The following Sub procedure assumes that the presentation PPTAutomation.ppt contains a macro called "AutomationTest."

     Sub PPTTest()
      Dim PPT as Object

      Set PPT = CreateObject("PowerPoint.Application")

      PPT.Presentations.Open "C:\My Documents\PPTAutomation.ppt", , ,False

      ' Note that the file name and the module
      ' name are required to path the macro correctly.
      PPT.Run "PPTAutomation.ppt!Module1.AutomationTest"

   End Sub
				

Sub Procedure to Run an Existing Microsoft Word Macro

The following Sub procedure assumes that the document WordDoc.Doc contains a macro called "WordMacro."

      Sub WDTest()
      Dim WD as Object

      Set WD = CreateObject("Word.Application")

      WD.Documents.Open "C:\My Documents\WordDoc.Doc"

      ' Note that the project name and module name are required to
      ' path the macro correctly.
      WD.Run "Project.Module1.WordMacro"

   End Sub