ACC: Microsoft Access Is Visible When Started Through Automation (167659)


The information in this article applies to:

  • Microsoft Access for Windows 95 7.0
  • Microsoft Access 97
This article was previously published under Q167659
Advanced: Requires expert coding, interoperability, and multiuser skills.

SYMPTOMS

When you use Automation to create an instance of Microsoft Access, the Microsoft Access application window is visible automatically.

This article assumes that you are familiar with Visual Basic for Applications and with creating Microsoft Access applications using the programming tools provided with Microsoft Access. For more information about Visual Basic for Applications, please refer to your version of the "Building Applications with Microsoft Access" manual.

RESOLUTION

Use the CreateObject function to start a new instance of Microsoft Access, and then use the Windows application programming interface (API) procedure, ShowWindow, to hide the instance.
  1. Start Microsoft Access and open the sample database Northwind.mdb.
  2. Create a module and type the following lines in the Declarations section:
    Option Explicit

Private Declare Function ShowWindow Lib "User32" _
      (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long
  3. Type the following procedure:
          Sub StartAccessHidden()
      Dim sw As Long
      Dim appAccess As Object
      On Error Resume Next

      ' Start an instance of Microsoft Access.
      Set appAccess = CreateObject("Access.Application")

      ' Hide the instance of Microsoft Access.
      sw = ShowWindow(appAccess.hWndAccessApp, False)
      If Err.Number = 0 Then
         MsgBox "The instance of Microsoft Access was started " & _
                "and hidden successfully.  Click OK to view the " & _
                "instance."

         ' Unhide the instance of Microsoft Access.
         appAccess.Visible = True
         appAccess.UserControl = True
      Else
         Err.Clear
         MsgBox "The instance of Microsoft Access was not " & _
                "started successfully."
      End If
      End Sub
  4. To test this procedure, type the following line in the Debug window, and then press ENTER: 
    StartAccessHidden
    Note that an instance of Microsoft Access is started and is immediately hidden. After you click OK in the message box, the instance of Microsoft Access becomes visible. To close the second instance of Microsoft Access, click Exit on the Microsoft Access File menu.

STATUS

Microsoft has confirmed that this is a problem in the Microsoft products that are listed at the beginning of this article. This problem was corrected in Microsoft Access 2000.

MORE INFORMATION

Most applications are not visible by default when you activate them with Automation. Although Microsoft Access exposes a Visible property, it does not hide or show the instance of Microsoft Access. Instead, the Visible property controls whether or not Microsoft Access is minimized.

Steps to Reproduce Problem

  1. Open the sample database Northwind.mdb.
  2. Create a module and type the following line in the Declarations section if it is not already there:
    Option Explicit
  3. Type the following procedure:
    Sub StartAccess()

   Dim appAccess As Object

   ' Start an instance of Microsoft Access.
   Set appAccess = CreateObject("Access.Application")

End Sub
  4. To test this procedure, type the following line in the Debug window, and then press ENTER. 
    StartAccess
    Note that an instance of Microsoft Access starts and is fully visible. To close the instance of Microsoft Access, click Exit on the Microsoft Access File menu.

REFERENCES

For more information about using Microsoft Access as an Automation server, please see the following article in the Microsoft Knowledge Base:

147816 ACC: Using Microsoft Access as an Automation Server

Modification Type:MinorLast Reviewed:10/11/2006
Keywords:kbbug kbfix kbinterop kbProgramming KB167659
©2004 Microsoft Corporation. All rights reserved.