PPT: Sample VB Code to Create Shape Using FreeForm Tool (165795)


The information in this article applies to:

  • Microsoft PowerPoint 98 Macintosh Edition
  • Microsoft PowerPoint 97 for Windows
This article was previously published under Q165795

SUMMARY

This article provides a sample Microsoft Visual Basic for Applications macro (Sub procedure) that uses the FreeForm tool to draw a shape that resembles a sine wave.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

Sample Visual Basic Procedure

Sub DrawWave()

   On Error Resume Next

   ' Dimension the variables that hold the height and width of
   ' the presentation.
   Dim lh As Long, lw As Long

   ' Get the slide height and width.
   lh = ActivePresentation.PageSetup.SlideHeight
   lw = ActivePresentation.PageSetup.SlideWidth

   ' Clear the error object and get the current slide number.
   Dim lSlideNum As Long
   Err.Clear
   lSlideNum = ActiveWindow.Selection.SlideRange.SlideNumber
   If Err.Number <> 0 Then

      ' Display error message.
      MsgBox Err.Description, vbExclamation

      ' Stop the macro.
      End
   End If

   ' Draw a line down the middle of the screen.
   With ActivePresentation.Slides(lSlideNum).Shapes
      .AddLine 0, lh \ 2, lw, lh \ 2
   End With

   ' Create the first point of the free form shape.
   Dim oShape As FreeformBuilder
   With ActivePresentation.Slides(lSlideNum).Shapes
      ' Places the free form tool at its initial point.
      Set oShape = .BuildFreeform(msoEditingAuto, 0, lh \ 2)
   End With

   ' Peak point.
   oShape.AddNodes msoSegmentCurve, msoEditingAuto, lw \ 4, 0

   ' Middle point.
   oShape.AddNodes msoSegmentCurve, msoEditingAuto, lw \ 2, lh \ 2

   ' Valley point.
   oShape.AddNodes msoSegmentCurve, msoEditingAuto, 3 * (lw \ 4), lh

   ' Ending point.
   oShape.AddNodes msoSegmentCurve, msoEditingAuto, lw, lh \ 2

   ' Convert all the points created into a shape. If you do not call
   ' ConvertToShape the free form object won't appear on your slide.
   oShape.ConvertToShape

End Sub

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type how to create a macro, click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type how to run a macro, click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

176476 OFF: Office Assistant Not Answering Visual Basic Questions

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

163435 VBA: Programming Resources for Visual Basic for Applications

Modification Type:MinorLast Reviewed:10/11/2006
Keywords:kbcode kbdtacode kbhowto kbmacro kbProgramming KB165795
©2004 Microsoft Corporation. All rights reserved.