PPT97: Sample VB Code Changes Source of Multiple Linked Objects (165369)

MORE INFORMATION

Sample Visual Basic Procedure

  'This macro loops through the presentation from the first slide to
   'the last and searches each slide for linked OLE objects. Once the
   'object has been found it is set to a new source document. This
   'macro can only change the source document to a single new source
   'document, though with some modifications, it could be expanded to
   'compare an existing source document to a list, and then make
   'substitutions based on matches found.

   Sub LinkSourceReplace()

   Dim i As Integer
   Dim k As Integer

   ' Set a for loop to go from slide 1 to the last slide in the
   ' presentation.
   For i = 1 To ActivePresentation.Slides.Count

      ' Select the slide based on the index value.
      With ActivePresentation.Slides(i)

         ' Loop through all the objects on the slide.
         For k = 1 To .Shapes.Count

            ' Use only shapes on the slide.
            With .Shapes(k)

               ' If the shape's type is an OLE object then...
               If .Type = msoLinkedOLEObject Then

                  ' Change the path to new source and set the update
                  ' type to Automatic.
                  With .LinkFormat
                     .SourceFullName = "c:\my documents\document.doc"
                     .AutoUpdate = ppUpdateOptionAutomatic
                  End With

               End If

            End With

         Next k

      End With

   Next i

   End Sub