ACC: Running a Microsoft Word 97 Macro Using Automation (160294)

MORE INFORMATION

By using Automation code in Microsoft Access, you can open a Microsoft Word 97 document and run a macro in the document.

The following examples use two methods, one that opens a Microsoft Word 97 document that is external to Microsoft Access, and one that opens a document that is embedded in a Microsoft Access form.

These examples assume that you have Microsoft Word 97 set up on your computer, that you have a document called C:\My Documents\WordTest.doc, and that a macro called Macro1 exists in the default template (Normal.dot).

Example 1: Run a Macro in an External Microsoft Word 97 Document

Open the sample database Northwind.mdb.
Create a new module in Design view.
On the Tools menu, click References.
Click Microsoft Word 8.0 Object Library in the Available References box. If that selection does not appear, click the Browse button and look for a file called Msword8.olb, which is installed in the C:\Program Files\Microsoft Office\Office folder by default.
Click OK in the References dialog box.

Type the following procedure in the module:

      Function RunWordMacro()
         Dim WordApp As Word.Application
         Dim WordDoc As Word.Document
         Set WordApp = CreateObject("Word.Application")
         Set WordDoc = WordApp.Documents.Open _
             ("C:\My Documents\Wordtest.doc")
         WordApp.Visible = True
         WordApp.Run "Macro1"

         ' Uncomment the next line of code to print the document.
         ' WordDoc.PrintOut Background:=False

         ' Uncomment the next line of code to save the modified document.
         ' WordDoc.Save

         WordApp.Quit SaveChanges:=wdDoNotSaveChanges
         Set WordApp = Nothing
      End Function

To test this function, type the following line in the Debug window, and then press ENTER:
?RunWordMacro()
Note that Microsoft Word 97 opens the C:\My Documents\Wordtest.doc document, and then runs the macro called Macro1.

Example 2: Run a Macro in an Embedded Microsoft Word 97 Document

Open the sample database Northwind.mdb.
Open any module in Design view.
On the Tools menu, click References.
Click Microsoft Word 8.0 Object Library in the Available References box. If that selection does not appear, click the Browse button and look for a file called Msword8.olb, which is installed in the C:\Program Files\Microsoft Office\Office folder by default.
Click OK in the References dialog box.
Create a new form not based on any table or query in Design view.
Add an unbound object frame control to the detail section of the form.
When the Insert Object dialog box appears, click Create From File, and then click the Browse button to select your C:\My Documents\WordTest.doc file.
Click Open in the Browse dialog box, and then click OK in the Insert Object dialog box.

Set the following properties for the unbound object frame control:

       Unbound Object Frame
       --------------------
       Name: MacroObj
       Locked: No

Add a command button to the form; set its Name property to RunWordMacro and set its OnClick property to the following event procedure:

       Private Sub RunWordMacro_Click()
          Dim WordObj As Word.Application

          ' Open Microsoft Word 97 in place and activate it.
          Me![MacroObj].Verb = -4
          Me![MacroObj].Action = 7

          Set WordObj = Me![MacroObj].Object.Application
          WordObj.Run "Macro1"
          Set WordObj = Nothing
       End Sub

Save the form as frmMacro, and then open it in Form view.
Click the command button on the form and note that the macro runs while the document is edited in place in the control on your form.