Visual Basic Example to Open a RecordSet Using DAO (148361)

MORE INFORMATION

Visual Basic Code Example

1. Insert a Visual Basic module into a new Microsoft Excel workbook.
2. Create a reference to the Microsoft DAO object library. In Microsoft Excel 97 the DAO library will be version 3.5. In Microsoft Excel 7.0 the DAO library will be version 3.0.
3. Type the following code into the module sheet:

       ' This code assumes you have Microsoft Access 7.0 installed and have
      ' the Northwind.mdb sample database installed in the default
      ' location.
   
      Sub CreateRecordSet()
   
        Dim oldDbName As String
        Dim wspDefault As Workspace
        Dim dbsNorthwind As Database
        Dim strSQL As String
        Dim rstFromQuery As Recordset
   
        'Set the path to the database
        oldDbName = "C:\Msoffice\access\samples\Northwind.mdb"
   
        'Create a default workspace Object
        Set wspDefault = DBEngine.Workspaces(0)
   
        'Create a Database object
        Set dbsNorthwind = wspDefault.OpenDatabase(oldDbName)
   
        'The SQL statement
        strSQL = "SELECT Employees.LastName, Employees.FirstName, " & _
           "Employees.Country FROM Employees Employees " & _
           "WHERE (Employees.Country='USA')"
   
        'Create a Snapshot Type Recordset from the SQL query
        Set _
        rstFromQuery = dbsNorthwind.OpenRecordset(strSQL,dbOpenSnapshot)
   
        'Show the number of fields returned
        MsgBox "there are " & rstFromQuery.Fields.Count & _
        " fields that were returned"
   
        'Move to the last record in the recordset
        rstFromQuery.MoveLast
   
        'Show the number of records returned
        MsgBox "there are " & rstFromQuery.RecordCount & _
        " records that were returned"
   
     End Sub