PRB: COMTI Explicit Security does not succeed because COMTIIntrinsics property is set to False by default (318555)

MORE INFORMATION

1. Paste the code into a text (.txt) file named ComtiCheck.vbs.
2. Run the code from a command prompt as follows:

   C:\>ComtiCheck "COMTI Utilities"

3. If the name of the application package where the Comtisec.dll is installed has been changed from the default name of COMTI Utilities, use the appropriate application package name.

VBScript Sample Code

'Get arguments.
   Set objArgs = WScript.Arguments

   if objArgs.Count <> 1 then
       WScript.Echo "Usage: ComtiCheck 'COMTISEC' --- where COMTISEC is the package name"
       WScript.Quit (0)
   end if

   applicationName = UCASE(objArgs(0))

   Set catalog = CreateObject("COMAdmin.COMAdminCatalog.1")
   Set applications = catalog.GetCollection("Applications")

   applications.Populate
   numApplications = applications.Count

   For i = numApplications - 1 To 0 Step -1
       If UCASE(applications.Item(i).Value("Name")) = applicationName Then
           Set application = applications.Item(i)
           Exit For
       End If
       If i = 0 Then
         WScript.Echo "Package Name Not Found - " & applicationName
         WScript.Quit (0)
       End If       
   Next

   Set components = applications.GetCollection("Components", application.Value("ID"))
   components.Populate
   numComponents = components.Count

   If numComponents = 0 Then
     wscript.echo "No components installed in package - " & applicationName
     wscript.quit (0)
   End If

   For i = numComponents - 1 To 0 Step -1
     	   Set component = components.Item(i)
           If component.Value("COMTIIntrinsics") Then
                  wscript.echo components.Item(i).Name & " is set to true"
           Else
                  wscript.echo components.Item(i).Name & " is set to false"
           End If
   Next
				

If COMTIIntrinsics is False for COMTI.HostSecurityContext

1. Open the COMTI Manager and move to the COMTI Utilities Application Package.
2. Right-click the COMTI Utilities Application Package, and then click Properties.
3. On the Advanced tab, verify that the Disable changes check box is clear, and then click OK.
4. Run the following script:
   1. To use the script, copy and paste it to a text document named ComtiSet.vbs, and then run the code from a command prompt as follows:

      C:\>ComtiSet "COMTI Utilities" all 1
      							

      This sets the COMTIIntrinsics property to True.
   2. To set the property to False, enter a 0 instead of 1 in the argument list.
   3. If the name of the Application Package where the comtisec.dll is installed has been changed from the default COMTI Utilities, use the appropriate application package name.
      
      If there are other components installed in the application package (not a recommended configuration), you can use the ProgID (COMTI.HostSecurityContext) to set the COMTIIntrinsics property on only that component.
5. After you run the following script, rerun the VBScript sample code from earlier in this section to verify that the COMTIIntrinsics property is set correctly.

'Get arguments.
   Set objArgs = WScript.Arguments

   if objArgs.Count <> 3 then
       WScript.Echo "ComtiSet"
       WScript.Echo ""
       WScript.Echo "Usage:"
       WScript.Echo "ComtiSet [appname], [progid], [value]"
       WScript.Echo "[appname]: Name of the application"
       WScript.Echo "[progid]:  ProgID of the component to change. Type 'all' for all components."
       WScript.Echo "[value]:   0 for False, 1 for True"
       WScript.Quit (0)
   end if

   applicationName = UCASE(objArgs(0))
   componentProgID = objArgs(1)
   ComtiIntrinsics = objArgs(2)

   Set catalog = CreateObject("COMAdmin.COMAdminCatalog.1")
   Set applications = catalog.GetCollection("Applications")

   applications.Populate
   numApplications = applications.Count

   For i = numApplications - 1 To 0 Step -1
       If UCASE(applications.Item(i).Value("Name")) = applicationName Then
           Set application = applications.Item(i)
           Exit For
       End If
       If i = 0 Then
         WScript.Echo "Package Name Not Found - " & applicationName
         WScript.Quit (0)
       End If       
   Next

   Set components = applications.GetCollection("Components", application.Value("ID"))
   components.Populate
   numComponents = components.Count

   If numComponents = 0 Then
     wscript.echo "No components installed in package - " & applicationName
     wscript.quit (0)
   End If

   For i = numComponents - 1 To 0 Step -1
       If components.Item(i).Name = componentProgID Or componentProgID = "all" Then
     	   Set component = components.Item(i)
           component.Value("COMTIIntrinsics") = ComtiIntrinsics
       End If
   Next
       
   components.SaveChanges
   applications.SaveChanges
   WScript.Echo "Changes All Complete"