How to use the CDOEX Library to create an Outlook Calendar folder in Visual Basic .NET (314372)

MORE INFORMATION

1. Start Microsoft Visual Studio .NET.
2. On the File menu, point to New, and then click Project.
3. In the Visual Basic Projects types list, click Console Application.
   
   By default, Module1.vb is created.
4. Add a reference to the CDOEX Library. To do so, follow these steps:
   1. On the Project menu, click Add Reference.
   2. Click the COM tab, locate Microsoft CDO for Exchange 2000 Library, and then click Select.
   3. In the Add References dialog box, click OK.
   4. If you are prompted to generate wrappers for the libraries that you selected, click Yes.
5. Follow the same steps to add a reference to the Microsoft ActiveX Data Objects 2.5 Library.
6. In the code window, replace the code with the following:

   Module Module1
   
       Sub Main()
           'strFolderType    Name
           '
           'MailItems        IPF.Note
           'ContactItems     IPF.Contact
           'AppointmentItems IPF.Appointment
           'NoteItems        IPF.StickyNote
           'TaskItems        IPF.Task
           'JournalItems     IPF.Journal
   
           Dim sType as String = "IPF.Appointment"
   
           Dim oCn As ADODB.Connection = New ADODB.Connection()
           Dim oRc As ADODB.Record = New ADODB.Record()
   
           Dim oFields As ADODB.Fields
           Dim oField As ADODB.Field
   
           Dim sFolderTypeProperty As String
           sFolderTypeProperty = "http://schemas.microsoft.com/exchange/outlookfolderclass"
   
           ' TODO: Replace with your new folder URL
           Dim sFdUrl As String
           sFdUrl = "http://<ExchServer>/Exchange/<UserAlias>/Inbox/NewFolder"
           oCn.Provider = "exoledb.datasource"
   
           oCn.Open(sFdUrl, "", "", 0)
           If oCn.State = 1 Then
               Console.WriteLine("Good Connection")
           Else
               Console.WriteLine("Bad Connection")
               Return
           End If
   
           oRc.Open(sFdUrl, oCn, _
            ADODB.ConnectModeEnum.adModeReadWrite, _
            ADODB.RecordCreateOptionsEnum.adCreateCollection, _
            ADODB.RecordOpenOptionsEnum.adOpenSource, _
            "", "")  ' adOpenAsync is not supported	
   
           If oRc.State = ADODB.ObjectStateEnum.adStateOpen Then
               Console.WriteLine("Record Open Success")
           Else
               Console.WriteLine("Record Open Fails")
               Return
           End If
   
           ' Add Folder type
           oFields = oRc.Fields
           oField = oFields.Item(sFolderTypeProperty)
           oField.Value = sType
   
           oFields.Update()
   
           oRc.Close()
           oCn.Close()
   
           oCn = Nothing
           oRc = Nothing
           oFields = Nothing
           oField = Nothing
       End Sub
   
   End Module
   					

7. Search for TODO in the code, and then modify the code for your environment.
8. Press F5 to build and to run the program.
9. Make sure that the Outlook Calendar folder was created.