ACC2002: How to Use Server Filters on Data Access Pages Without a Web Server (285162)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. The following steps demonstrate how to create a page that is based on the Customers table. When you open the page or click the New Filter button, the script prompts you for a list of countries. The script then limits the number of records that are returned based on the countries that you entered. You can return all records by leaving the list empty.

CAUTION: If you follow the steps in this example, you modify the sample database Northwind.mdb. You may want to back up the Northwind.mdb file and follow these steps on a copy of the database.

1. Open the sample database Northwind.mdb.
2. Create a new page in Design view.
3. If the field list is not displayed, on the View menu, click Field List.
4. From the Customers table, drag the CustomerID, the CompanyName, the City, the Region, and the Country fields to the page.
5. Add a command button to the page, and then set the following properties:

      ID: cmdFilter
      Inner Text: New Filter
   					

6. On the Tools menu, point to Macro, and then click Microsoft Script Editor.
7. On the Edit menu, point to Insert Script Block, and then click Client. This will insert script tags as follows:

   <script language=vbscript>
   <!--
   
   -->
   </script>
   					

8. Type or paste the following function within the script tags:

   Function SetServerFilter()
   
      Dim strFilter, myFilter
   
      strPrmt = "What country do you want to filter by?" & vbCrLf & _
                "Separate the list of countries by a semicolon (;)." & _
                vbCrLf & "To return all records, leave the box empty."
   
      'Prompt the user for list of countries that are to be returned.
      strFilter = InputBox(strPrmt)
   
      If strFilter = "" Then
         'Clear the filter criteria when nothing is typed in the input box.
         'All records are returned in this case.
         myFilter = ""
      Else
         'Loop through the user's list until there is only one country left. 
         Do Until InStr(strFilter, ";") = 0
            'Add the first country from the list to the filter criteria.
            myFilter = myFilter & "[Country] = " & Chr(39) & _
                       Left(strFilter, InStr(strFilter, ";") - 1) & _
                       Chr(39) & " OR "
            'Remove the first country from the list.
            strFilter = Right(strFilter, Len(strFilter) - InStr(strFilter, _
                        ";") - 1)
         Loop
         'Add the final country from the user's list to the filter criteria.
         myFilter = myFilter & "[Country] = " & Chr(39) & strFilter & Chr(39)
      End If
   
      'Set the server filter.
      MSODSC.RecordsetDefs.Item(0).ServerFilter = myFilter
   End Function
   					

9. In the Object list, click cmdFilter, and in the Event list, click onclick. This will insert script tags as follows:

   <SCRIPT language=vbscript for=cmdFilter event=onclick>
   <!--
   
   -->
   </SCRIPT>
   					

10. Add the following single line of script within the tags:

    SetServerFilter
    						

    The script should now appear as follows:

    <SCRIPT language=vbscript for=cmdFilter event=onclick>
    <!--
    SetServerFilter
    -->
    </SCRIPT>
    					

11. Save the page as dapSvrFilterEx, and then close the Microsoft Script Editor.
12. On the View menu, click Page View.
13. Click the Filter button, and then in the input box, type Canada; Mexico; USA. Click OK. Approximately 22 records should be returned.