BUG: CDO: Copying or Moving Hidden Messages Makes Them Visible (266734)

MORE INFORMATION

Steps to Reproduce Behavior

1. Open a new Microsoft Visual Basic project.
2. Add a button to the form. (The name of the button is Command1 by default.)
3. Make a reference to the Microsoft CDO 1.21 library.
4. In the Click event of the button, paste the following code:

   Option Explicit
   
   Private Sub Command1_Click()
       Dim objSession As Session
       Dim objHiddenMsgs As Messages
       Dim objHiddenMsg As Message
       Dim objHiddenMsgMove As Message
       Dim objFolderSource As Folder
       Dim objFolderDest As Folder
       
       ' Log on to the CDO session.
       Set objSession = CreateObject("MAPI.Session")
       objSession.Logon
   
       ' Delete the messages in the Hiddenmessages collection for the TestSource folder.
       Set objFolderSource = objSession.Inbox.Folders("TestSource")
       ' Debug.Print "Source Folder : " & objFolderSource.Name
       Set objHiddenMsgs = objFolderSource.HiddenMessages
       objHiddenMsgs.Delete
       
       ' Delete the messages in the Hiddenmessages collection for the TestDest folder.
       Set objFolderDest = objSession.Inbox.Folders("TestDest")
       ' Debug.Print "Dest Folder : " & objFolderDest.Name
       Set objHiddenMsgs = objFolderDest.HiddenMessages
       objHiddenMsgs.Delete
   
       ' Add a new hidden message in the TestSource folder.
       Set objHiddenMsg = objFolderSource.HiddenMessages.Add
       objHiddenMsg.Subject = "Test Hidden Message"
       objHiddenMsg.Text = "This the Message body..."
       objHiddenMsg.Update
       
       ' Check the hidden messages before move.
       Debug.Print "Before Move :"
       Debug.Print "TestSource contains " & _
                   objFolderSource.HiddenMessages.Count & " hidden messages"
       Debug.Print "TestDest contains " & _
                   objFolderDest.HiddenMessages.Count & " hidden messages"
       
       ' Move the hidden message from TestSource folder to TestDest folder.
       Set objHiddenMsgMove = objHiddenMsg.MoveTo(objFolderDest.ID)
       objHiddenMsgMove.Update
       
       ' Check the hidden messages after move.
       Debug.Print "After Move :"
       Debug.Print "TestSource contains " & _
                   objFolderSource.HiddenMessages.Count & " hidden messages"
       Debug.Print "TestDest contains " & _
                   objFolderDest.HiddenMessages.Count & " hidden messages"
       
       ' Log off.
       objSession.Logoff
       
       ' Claen up.
       Set objSession = Nothing
       Set objHiddenMsgs = Nothing
       Set objHiddenMsg = Nothing
       Set objHiddenMsgMove = Nothing
       Set objFolderSource = Nothing
       Set objFolderDest = Nothing
       Unload Me
   End Sub
   					

5. Start Microsoft Outlook and create two folders named TestSource and TestDest under the Inbox folder.
6. Press F5 to run the code.