XCLN: How to Create an Appointment Folder Using WebDAV (259853)

MORE INFORMATION

1. Create a public folder named Aspapps under Public Folders. Copy and paste the following code to Notepad, modify the code to reflect your server name, and then save the code in the Aspapps folder as the Mkcolappt.asp file.

   <%@ language=vbscript %>
   <%
   option explicit
   '----------------------------------------------------------------------
   'Example: Create an appointment folder in the MAPI public folder tree
   '----------------------------------------------------------------------
   Dim newFolderURL
   
   Dim XMLreq 'XML activeX object to process the request to create the folder
   Dim sReq 'XML request string 
    
   newFolderURL = "http://ServerName/public/MKCOLAppt"     
   
   'Use XML to create the new folder 
   set XMLreq = createobject("microsoft.xmlhttp")
   
   XMLreq.open "MKCOL", newFolderURL, false
   XMLreq.setrequestheader "Content-Type", "text/xml"
   
   sReq =  "<?xml version='1.0'?>"
   sReq = sReq & "<a:propertyupdate xmlns:a='DAV:' xmlns:ex='http://schemas.microsoft.com/exchange/'>"
   sReq = sReq & "<a:set><a:prop>"
   sReq = sReq & "<ex:outlookfolderclass>IPF.Appointment</ex:outlookfolderclass>"
   sReq = sReq & "</a:prop></a:set></a:propertyupdate>"
   
   'send the request to set the search criteria
   XMLreq.send(sReq)
   
   
   'display the results
   if (XMLreq.status >= 200 and XMLreq.status < 300) then
     Response.Write("<P>Success!   " & "Results = " & XMLreq.status & ": " & XMLreq.statusText  & "</P>")
   else
     Response.Write("<P>Request Failed.  Results = " & XMLreq.status & ": " & XMLreq.statusText & "</P>")
   end if
   	
   %>
   					

2. Run the .asp file in Microsoft Internet Explorer by using the following path:

   http://server_name/public/aspapps/mkcolappt.asp