XL97: How to Programmatically Reset a Workbook to Default Styles (247980)

SUMMARY

The following Microsoft Visual Basic for Applications Sub procedure removes all styles in a Microsoft Excel workbook and then adds back the default styles you see in a new workbook. This macro may be helpful for removing extra styles added to a workbook infected by a macro virus.

This macro uses the Workbooks.Add method, which bypasses templates in the startup directories. Because of this, it works correctly even if templates in the startup directories have had extra styles added to them.

NOTE: The Excel File Recovery Macro has an option to remove all formatting from a workbook. For additional information about how to download the Excel File Recovery Macro, click the article number below to view the article in the Microsoft Knowledge Base:

142117 XL: Summary of Methods to Recover Data from Corrupted Files

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Partner or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Partners, please visit the following Microsoft Web site:

http://www.microsoft.com/partner/referral/

For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site:

http://support.microsoft.com/default.aspx?scid=fh;EN-US;CNTACTMS

The following macro removes the styles from the currently active workbook. If you type this code into a new workbook, please make sure to activate the workbook from which you want to reset the styles before running the macro.

Sub RebuildDefaultStyles()

'The purpose of this macro is to remove all styles in the active
'workbook and rebuild the default styles. "Normal" cannot be
'deleted. Therefore the macro does not attempt to delete it.
'It rebuilds the default styles by merging them from a new workbook.

    'Dimension variables.
    Dim MyBook As Workbook
    Dim tempBook As Workbook
    Dim CurStyle As Style
    
    'Set MyBook to the active workbook.
    Set MyBook = ActiveWorkbook
    
    'Delete all the styles in the workbook.
    For Each CurStyle In ActiveWorkbook.Styles
        If CurStyle.Name <> "Normal" Then CurStyle.Delete
    Next CurStyle

    'Open a new workbook.
    Set tempBook = Workbooks.Add
    
    'Disable alerts so you may merge changes to the Normal style
    'from the new workbook.
    Application.DisplayAlerts = False
    
    'Merge styles from the new workbook into the existing workbook.
    MyBook.Styles.Merge Workbook:=tempBook
    
    'Enable alerts.
    Application.DisplayAlerts = True
    
    'Close the new workbook.
    tempBook.Close

End Sub

REFERENCES

For additional information about how to identify and remove the PLDT/CAR/SGV macro viruses, click the article number below to view the article in the Microsoft Knowledge Base:

176807 XL: How to Identify and Remove PLDT/CAR/SGV Macro Viruses

For more information about how to use the sample code in this article, click the article number below to view the article in the Microsoft Knowledge Base:

173707 OFF97: How to Run Sample Code from Knowledge Base Articles