PPT2000: Code to Display the Number of Slides or Shapes Selected (222777)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. NOTE: The following macro examples work only in PowerPoint. Visual Basic for Applications macros are not supported by the Microsoft PowerPoint Viewer. For additional information, click the following article number to view the article in the Microsoft Knowledge Base:

Sample Visual Basic Procedure

   Sub HowMany()

      Const StandardMessage As String = "Please select a slide or a" _
      & " shape and run the macro again."

      ' Define a selection object.
      Dim TheSelection As PowerPoint.Selection

      ' String used to create the message box.
      Dim Message As String

      Dim NumberOfObjects As Long

      ' Assign the TheSelection to the current selection.
      Set TheSelection = ActiveWindow.Selection

      ' Determine the type of selection.
      Select Case TheSelection.Type

         ' See whether a selection was made.
         Case ppSelctionNone

            Message = "You don't have anything selected. " _
               & StandardMessage

         ' See whether a slide is selected.
         Case ppSelectionSlides

            ' Get the number of slides selected.
            NumberOfObjects = TheSelection.SlideRange.Count

            If NumberOfObjects = 1 Then
               Message = "You have one slide selected."
            Else
               Message = "You have " & NumberOfObjects _
                  & " slides selected."
            End If

         Case ppSelectionShapes

            ' Get the number of shapes selected.
            NumberOfObjects = TheSelection.ShapeRange.Count
            If NumberOfObjects = 1 Then
               Message = "You have one shape selected."
            Else
               Message = "You have " & NumberOfObjects _
                  & " shapes selected."
            End If

         Case ppSelectionText

            Message = "You have text selected. " & StandardMessage

         Case Else

            MsgBox "Do not recognize your selection.", vbCritical
            End

      End Select

      ' Display the message box.
      MsgBox Message, vbInformation

   End Sub