WD2000: SaveAs Method Overwrites Existing Documents (211242)

WORKAROUND

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. To work around this problem, you can use the following Microsoft Visual Basic for Applications sample macro.

The following macro tests to see whether the file you intend to save already exists in the current folder. If it does, the macro prompts you with a message asking whether you want to overwrite the existing file. Clicking Yes overwrites the file with the new file. Clicking No displays the Save As dialog box (on the File menu), allowing you to enter a different name for the file.

Sub SaveAsExample()
   Dim strSaveAsName As String
   Dim strMsg As String
   ' Replace the following document name "MyDoc.Doc" with
   ' the name you want to use to "Save As."
   strSaveAsName = "MyDoc.Doc"
   ' Message to return if file exists.
   strMsg = "Do you want to replace the existing " & strSaveAsName & "?"
   ' Check if the file exists.
   If Dir(strSaveAsName & "*") = "" Then
      ' If file does not exist, save without prompting.
      ActiveDocument.SaveAs FileName:=strSaveAsName
   Else
      ' If file does exist, prompt with warning message.
      ' Check value of button clicked in message box.
      Select Case MsgBox(strMsg, vbYesNoCancel + vbExclamation)
         Case vbYes
         ' If Yes was chosen, save and overwrite existing file.
            ActiveDocument.SaveAs FileName:=strSaveAsName
         Case vbNo
         ' If No was chosen, prompt for file name
         ' using the File SaveAs dialog box.
            With Dialogs(wdDialogFileSaveAs)
               .Name = ""
               .Show
            End With
         Case Else
         ' If Cancel was chosen, do nothing.
      End Select
   End If
End Sub