How to fill a record with data from a previous record automatically in Access 2000 and 2002 and Office Access 2003 (210236)


The information in this article applies to:

  • Microsoft Office Access 2003
  • Microsoft Access 2002
  • Microsoft Access 2000
This article was previously published under Q210236
Moderate: Requires basic macro, coding, and interoperability skills.

This article applies only to a Microsoft Access database (.mdb).

For a Microsoft Access 97 version of this article, see 136127.

SUMMARY

When you are creating new records by using a form, you may want to speed the data entry process by having fields in the new record fill automatically with values from the previous record. This article shows you how to create a sample Visual Basic for Applications function called AutoFillNewRecord() that enables you to fill selected fields (or all fields) in a new record with values from the previous record automatically.

Note This article explains a technique that is demonstrated in the sample file that is named FrmSampl.mdb.

For additional information about how to obtain this sample file, click the following article number to view the article in the Microsoft Knowledge Base:

233324 The Microsoft Access 2000 sample forms database available in Download Center



Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. NOTE: The sample code in this article uses Microsoft Data Access Objects. For this code to run properly, you must reference the Microsoft DAO 3.6 Object Library. To do so, click References on the Tools menu in the Visual Basic Editor, and make sure that the Microsoft DAO 3.6 Object Library check box is selected.

MORE INFORMATION

One technique that you can use to speed repetitive data entry for the field that contains the insertion point is to press CTRL+APOSTROPHE (') to retrieve the value from the previous record.

Another technique is to use the AutoFillNewRecord()function described later in this article. You can call this function from a form's OnCurrent property event procedure to fill all the fields in a new record using data from the previous record. If you want to fill only selected fields, you can create a text box and set the DefaultValue property with a semicolon-delimited list of control names to automatically fill, for example: 
   Text box:
   -----------------------------------------------
   Name: AutoFillNewRecordFields
   Visible: No
   DefaultValue: Phone;Company Name;City;State;Zip
To create and use the AutoFillNewRecord() function, follow these steps:
  1. Open the sample database Northwind.mdb.
  2. Create a module and type the following line in the Declarations section:
    Option Explicit
  3. Type the following procedure:
     
Function AutoFillNewRecord(F As Form)

   Dim RS As DAO.Recordset, C As Control
   Dim FillFields As String, FillAllFields As Integer
   
   On Error Resume Next
   
   ' Exit if not on the new record.
   If Not F.NewRecord Then Exit Function
   
   ' Goto the last record of the form recordset (to autofill form).
   Set RS = F.RecordsetClone
   RS.MoveLast
   
   ' Exit if you cannot move to the last record (no records).
   If Err <> 0 Then Exit Function
   
   ' Get the list of fields to autofill.
   FillFields = ";" & F![AutoFillNewRecordFields] & ";"
   
   ' If there is no criteria field, then set flag indicating ALL
   ' fields should be autofilled.
   FillAllFields = Err <> 0
   
   F.Painting = False
   
   ' Visit each field on the form.
   For Each C In F
      ' Fill the field if ALL fields are to be filled OR if the
      ' ...ControlSource field can be found in the FillFields list.
      If FillALLFields Or InStr(FillFields, ";" & (C.Name) & ";") > 0 Then
         C = RS(C.ControlSource)
      End If
   Next
   
   F.Painting = True
   
End Function
  4. Save the module as modAuto_Fill_New_Record.
  5. Open the Customers form in Design view. Change the OnCurrent property of the form to read as follows:
    =AutoFillNewRecord([Forms]![Customers])
  6. Add a text box to the form, and set the following properties:
       Text Box
   ----------------------------------------------------------
   Name: AutoFillNewRecordFields
   Visible: No
   DefaultValue: CompanyName;ContactName;ContactTitle;Address
    Note This sample setting for the text box works only in the Northwind sample database. For your own database, you can set the DefaultValue property with a semicolon-delimited list of control names.
When you go to a new record, the CompanyName, ContactName, ContactTitle, and Address fields are filled in automatically. If you want all fields to automatically be filled in, you can leave the DefaultValue property blank or omit putting the AutoFillNewRecordFields text box on the form.

REFERENCES

For more information about the For Loop, in the Visual Basic Editor, click Microsoft Visual Basic Help on the Help menu, type For Each...Next Statement in the Office Assistant or the Answer Wizard, and then click Search to view the topic.
Modification Type:MinorLast Reviewed:10/11/2006
Keywords:kbcode kbinfo kbProgramming KB210236
©2004 Microsoft Corporation. All rights reserved.