WD2000: VBA Routines to Determine If Line or Document Is Empty (201956)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
The following Visual Basic for Applications Sub procedure uses the predefined bookmark "\Line", in combination with the Empty function, to determine whether the current line is empty. Using this method detects text as well as inline objects (such as an inline graphic) or floating objects anchored to the current line (such as a text box or drawing object).

Sub IsLineEmpty()

   If ActiveDocument.Bookmarks("\Line").Empty Then
      MsgBox "The current line is empty."
   Else
      MsgBox "The current line is not empty."
   End If

End Sub
				

For more information about predefined bookmarks, in the Visual Basic Editor, click Microsoft Visual Basic Help on the Help menu, type Predefined Bookmarks in the Office Assistant or the Answer Wizard, and then click Search to view the topic.


The following Visual Basic for Applications Sub and Function procedures use the StoryRanges property to loop through the StoryRanges collection of the active document. Using this method detects text as well as inline objects (such as an inline graphic) or floating objects anchored to the current line (such as a text box or drawing object).

Sub YourMacro()

   ' Call the IsDocEmpty function.
   If IsDocEmpty() Then
      MsgBox "The document is empty."
   Else
      MsgBox "The document contains text, objects or empty lines."
   End If

End Sub
				

Function IsDocEmpty() As Boolean

   ' Initialize function to True.
   IsDocEmpty = True
   For Each astory In ActiveDocument.StoryRanges

      ' Check for text. If the length of the
      ' current story is greater than one, then
      ' there is either text or more than one
      ' empty line.
      If Len(astory.Text) > 1 Then
         IsDocEmpty = False
      End If

      ' Check for Objects.
      ' Note: If there are no objects within
      ' the current story range, an error occurs.
      On Error Resume Next
      If astory.ShapeRange.Count > 0 Then
         If Err = 0 Then
            IsDocEmpty = False
         Else
            On Error GoTo 0
         End If
      End If

      ' If something was found, then
      ' return to the calling routine with
      ' a value of False.
      If IsDocEmpty = False Then Exit Function

   Next

End Function
				

For more information about StoryRanges property, in the Visual Basic Editor, click Microsoft Visual Basic Help on the Help menu, type StoryRanges Property in the Office Assistant or the Answer Wizard, and then click Search to view the topic.