How To Create a Generic Error Handler for your Application (191474)

MORE INFORMATION

Steps to Reproduce Behavior

1. Create a new standard EXE project in Visual Basic. Form1 is created by default.
2. Add the following code to the Load method of Form1. This code causes two errors to occur when the form is loaded. The first error will be handled by the form load method. The second error will be passed to the generic error handler:

         Private Sub Form_Load()
         On Error GoTo FormLoadErr
         Err.Raise 76
         Err.Raise 70
         Exit Sub
   
         FormLoadErr:
         Select Case Err.Number  'Evaluate Error Number
            Case 76
               MsgBox "Form_Load Error Handler. Form Does Not Exist"
            Case Else
               AppWideErr (Err.Number) 'Pass Error to generic module
            End Select
         End Sub
   
   						

3. Add a CommandButton to the form. This code causes two errors to occur. The first error will be handled by the click method. The second error will be passed to the generic routine. Change the Caption property to "Cause Error 53 and 70." Add the following code to the Click method of the CommandButton:

         Private Sub Command1_Click()
         On Error GoTo Cmd1Err
            Err.Raise 53 'Handled locally
            Err.Raise 70 'Handled by generic module
         Exit Sub
   
         Cmd1Err:
         Select Case Err.Number
            Case 53
               MsgBox "Command 1 Error Handler"
            Case Else
               AppWideErr (Err.Number)
            End Select
            Resume Next  'Process the next (70) error
         End Sub
   
   						

4. Add a second CommandButton to the form. If an error occurred in this method, no error handler would be called. Change the Caption property to "Show Form 2." Add the following code to the Click event:

         Private Sub Command2_Click()
            'No error handling is coded in this method
            'AppWideErr would not be called
      Form2.Show 'Use VB's default error handling only
         End Sub
   
   						

5. Add a second form to the project. Add a CommandButton to the form. This CommandButton passes all errors to the generic error handler and does not perform any special processing for specific errors. Change the Caption property of the button to "Cause Error 17." Add code to the Click method as follows:

         Private Sub Command1_Click()
         On Error GoTo ThisSubErr
            Err.Raise 17
            Exit Sub
         ThisSubErr:
            AppWideErr (Err.Number)
         End Sub
   
   						

6. Add a module to the project. Add the following code to the module:

       Public Sub AppWideErr(lnErrNumber)
       Select Case lnErrNumber  'Evaluate error passed to routine
          Case 70
             'The following two lines of code should be typed on one line.
             'Added title to MsgBox to make it clearer where error message
             'came from.
             MsgBox "Generic Routine.  Access Denied.  See Net Administrator."
                 , , "AppWideErr"
             Exit Sub
          Case Else
             'The following two lines of code should be typed on one line.
             'Added title to MsgBox to make it clearer where error message
             'came from.
             MsgBox "Generic Routine. Unhandled Error: " + Err.Description +
                 " # " & lnErrNumber , , "AppWideErr"
             Exit Sub
       End Select
       End Sub
   						

7. Save and run the project. Note that some errors will be handled by the error routine specific to a method. The logic for each method invokes the generic AppWideErr procedure for any errors not explicitly handled by the method. The error number is passed as a numeric argument to AppWideErr.