OFF97: Graph8 Process Remains in Memory After Macro Ends (171383)

WORKAROUND

To work around this problem, close and then reopen the presentation that contains the Graph objects that were edited.

Method 1: Manually Close the Presentation

1. On the File menu, click Close.
   
   This process removes any Graph objects from memory that are associated with the presentation.
2. On the File menu, click Open.
   
   Open the presentation you just closed; no Graph objects are activated yet.

Method 2: Use a Visual Basic Macro to Close the Presentation

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.
The sample code assumes the following:

• The presentation that contains the Graph objects is the active presentation.
  
  -and-
  
• You are running this procedure from a presentation that is not the active presentation. For example, if you run this code from the presentation you are trying to close, the procedure ends after the ActivePresentation.Close statement, because you just closed the presentation that contains the code.

Sample Visual Basic Procedure

Sub ReloadPresentation()
   Dim strPresPathName As String
   Dim lCurrentView As Long
   Dim lSlideNumber As Long
   ' Determine what view the presentation is in.
   lCurrentView = ActiveWindow.ViewType
   ' If the active view is slide view, get
   ' the slide number.
   If ActiveWindow.ViewType = ppViewSlide Then
      lSlideNumber = ActiveWindow.View.Slide.SlideNumber
   End If
   ' Save the presentation, if needed.
   If ActivePresentation.Saved = msoFalse Then
      ActivePresentation.Save
   End If
   ' Get the name and path to the active presentation.
   strPresPathName = ActivePresentation.FullName
   ' Close the presentation.
   ActivePresentation.Close
   ' Reopen the presentation.
   Presentations.Open strPresPathName
   ' Restore the view.
   ActiveWindow.ViewType = lCurrentView
   ' If in slide view, restore the slide number.
   If ActiveWindow.ViewType = ppViewSlide Then
      ActiveWindow.View.GotoSlide lSlideNumber
   End If
End Sub