How To Extract Appointment Information from Schedule Plus 7.0 (161298)

SUMMARY

The OLE Scheduling Library exposes an object model for Microsoft Schedule Plus 7.0 that can be manipulated by the VBA language. This object model allows programmers to gain access to appointment information. This article provides a code sample of how to extract appointment information between two given dates from Schedule Plus.

MORE INFORMATION

Start a new Standard EXE project. Form1 is added by default.
Place a CommandButton on Form1.

Add the following code to the General Declarations section of Form1:

            Option Explicit

      Private Sub Command1_Click()
         GetAppointments "06/03/96", "08/03/96" 'dd/mm/yy format
      End Sub

      Sub GetAppointments(sStartdate As String, sEndDate As String)
         Dim objSchdPlus As Object
         Dim gobjappt As Object
         Dim objappt As Object
         Dim objitem As Object
         Dim obatt As Object
         Screen.MousePointer = vbHourglass
         Set objSchdPlus = CreateObject("SchedulePlus.Application")
         objSchdPlus.Logon
         Set gobjappt = objSchdPlus.ScheduleSelected
         Print objSchdPlus.UserName
         Set objappt = gobjappt.singleappointments
         Set objitem = objappt.Item()
         Print objappt.Rows
         While Not objappt.IsEndOfTable
            Set objitem = objappt.Item()
            If CDate(objitem.start) >= _
               CDate(Format$(sStartdate, "dd/mm/yy") & " 00:00:00") And _
               CDate(objitem.end) _
               <= CDate(Format$(sEndDate, "dd/mm/yy") & " 23:59:59") Then
               Print "Starts " & objitem.start & "---" & "Ends ";
               Print objitem.end
               Print "Appointment := " & objitem.Text
            End If
            objappt.Skip
         Wend
         Screen.MousePointer = vbArrow
         MsgBox "Done"
      End Sub

Press the F5 key to run the project. When you click on the button, the appointments that fall into the date range specified will be printed on the form.

REFERENCES

OLE Scheduling is documented in the Microsoft Schedule+ Programmer's Guide found under Microsoft Exchange Server in the BackOffice SDK on the Microsoft Developer Network (MSDN).

The Mastering Series for Exchange Development, also available from Microsoft, has extensive Visual Basic code samples and explanations relating to OLE Scheduling.