#!/bin/csh
#
# Copyright (c) 1993-1996 CheckPoint Software Technologies Ltd.
# All Rights Reserved
#
# THIS IS AN UNPUBLISHED PROPRIETARY SOURCE CODE OF CHECKPOINT SOFTWARE
# TECHNOLOGIES LTD. The copyright notice above does not evidence any actual
# or intended publication of such source code.
#
# $Header: /fw/cvs/fw-1/fwutil/status_alert.csh,v 1.4.2.1 1996/04/11 09:59:21 yoav Exp $
#
set input = $<
set inp = ( $input )
set more
set new=unknown
set old=unknown
set date
set timex
set host=unknown_host

while ($#inp)
	switch ($inp[1])
		case "date=*":
			set date = `echo $inp[1] | sed 's/date=//'`
			breaksw
		case "time=*":
			set timex = `echo $inp[1] | sed 's/time=//'`
			breaksw
		case "hostname=*":
			set host = `echo $inp[1] | sed 's/hostname=//'`
			breaksw
		case "old=*":
			set old = `echo $inp[1] | sed 's/old=//'`
			breaksw
		case "new=*":
			set new = `echo $inp[1] | sed 's/new=//'`
			breaksw
		default:
			set more = "$more $inp[1]"
			breaksw
	endsw
	shift inp
end
echo "" $date $timex status ${host}: " " switching from old state \'$old\' \
				to new state \'$new\' $more |\
	alert
